將CNF中具有命題公式的字符串解析為haskell中的DIMACS嵌套int列表

Question

我想將CNF中帶有命題公式的字符串解析為DIMACS，從而在haskell中嵌套一個int列表。 該格式適用於haskell picosat綁定，該綁定似乎比SAT解算的其他選項更具性能。

問題是實現此功能的代碼太復雜了，現在我正在尋找一個可能不很明顯的錯誤。

（我的方法是使用haskell hatt程序包，更改程序包，以便它使用String而不是單個字符來表示變量名稱，使用hatt解析表達式，然后將結果表達式轉換為DIMACS格式。）

我想解析一個表示CNF表示法中的命題公式的字符串（請參見下面的示例）。 結果應該是一個嵌套的整數列表。 因此，結果應該是適合solveAll那是的一部分的Haskell picosat綁定 。

輸入：

-- "&" ... conjunction
-- "|" ... disjunction
-- "-" ... not operator

let myCNF = "GP  &  (-GP  |  Ma)  &  (-Ma  |  GP)  &  (-Ma  |  TestP)  &  (-Ma  |  Alg)  &  (-Ma  |  Src)  &  (-Ma  |  Hi)  &  (-Ma  |  Wg | X | Y) & -Z"

結果：

-- DIMACS format
-- every Variable (e.g., "GP") gets a number, say GP gets the int num 1
-- in case of not GP (i.e., "-GP") the int number representing the variable is negative, thus -1

-- Note: I hope I didn't do a type
let myresult = [[1], [-1, 2], [-2, 1], [-2, 3], [-2, 3], [-2, 5], [-2, 6], [-2, 7, 8, 9], [-10]]

let myvars = ["GP", "Ma", "TestP", "Alg", "Src", "Hi", "Wg", "X", "Y", "Z"]

-- or alternativly the variables are stored in an associative array
let varOtherWay = (1, GP), (2, Ma) (3, TestP), (4, Alg), (5, Src), (6, Hi), (7, Wg), (8, X), (9, Y), (10, Z)

Answer 1

您可能不需要parsec來讀取CNF中的語句，可以使用map (splitOn "|") . splitOn "&"提取變量map (splitOn "|") . splitOn "&" map (splitOn "|") . splitOn "&" -其余的只是將整數分配給變量：

import qualified Data.Map as M 
import Data.List.Split
import Control.Monad.State 

deleteMany c [] = []
deleteMany c (x:xs) 
  | x`elem`c  =     deleteMany c xs
  | otherwise = x : deleteMany c xs

parseStatement :: String -> ( [[Int]] , M.Map Int String )
parseStatement = 
 f . flip runState (M.empty, 1) . mapM (mapM (readVar . toVar)) . varsOf . deleteMany "() "
  where 
    f (r, (m, _)) = (r , M.fromList $ map (uncurry (flip (,))) $ M.toList m)

    varsOf = map (splitOn "|") . splitOn "&"

    toVar ('-':v) = (True , v)
    toVar v       = (False, v)

    readVar (b,v) = do 
      (m, c) <- get 
      case M.lookup v m of 
        Nothing -> put (M.insert v c m, c+1) >> return (neg b c)
        Just n  ->                              return (neg b n)

    neg True  = negate
    neg False = id

也許parsec版本對於錯誤處理或集成到更大的解析器中仍然很有趣：

parseStatement = parse statement "" . deleteMany " "

statement = sepBy1 clause (char '&')

clause = between (char '(') (char ')') x <|> x
  where x = sepBy1 var (char '|')

var = do
  n <- maybe False (const True) <$> optionMaybe (char '-')
  v <- many1 (noneOf "&|-() ")
  return (n, v)

Answer 2

我維護您提到的picosat綁定。 看到此問題后，我在picologic添加了一個新的picologic包，該包基於picosat進行解析並使用命題公式進行轉換並將其提供給SAT解算器。

import Picologic

p, q, r :: Expr
p = readExpr "~(A | B)"
q = readExpr "(A | ~B | C) & (B | D | E) & (D | F)"
r = readExpr "(φ <-> ψ)"

ps = ppExprU p
-- ¬(A ∨ B)
qs = ppExprU q
-- ((((A ∨ ¬B) ∨ C) ∧ ((B ∨ D) ∨ E)) ∧ (D ∨ F))
rs = ppExprU (cnf r)
-- ((φ ∧ (φ ∨ ¬ψ)) ∧ ((ψ ∨ ¬φ) ∧ ψ))

main :: IO ()
main = solveProp p >>= putStrLn . ppSolutions
-- ¬A ¬B
-- ¬A B
-- A ¬B

請參閱： http ： //hackage.haskell.org/package/picologic