如何將快捷方式固定到NSIS的開始菜單？

Question

我有一個NSIS安裝程序腳本，該腳本調用CreateShortcut將條目添加到開始菜單。 但是，我想在新創建的快捷方式中將選項設置為“固定到開始菜單”。

這可能嗎？ 我已經看到了一些有關如何執行此操作的VBScript示例 ..那是我對NSIS的唯一選擇，還是有更好的方法？

Answer 1

Windows 8應該自動為您固定它， 而8.1不會 。

雖然可以模擬固定快捷方式， 但實際上並沒有這樣做 。

如果您想作惡而不遵循指南，可以使用此插件 ...

Answer 2

使用StdUtils插件的InvokeShellVerb函數可以做到這一點。

適用於Windows 7及更高版本。

這是為后代保留的示例 ...

!include 'StdUtils.nsh'

RequestExecutionLevel user ;no elevation needed for this test
ShowInstDetails show

Section
    IfFileExists "$SYSDIR\mspaint.exe" +3
    MessageBox MB_ICONSTOP 'File does not exist:$\n"$SYSDIR\mspaint.exe"$\n$\nExample cannot run!'
    Quit
SectionEnd

Section
    DetailPrint "Going to pin MSPaint..."
    ${StdUtils.InvokeShellVerb} $0 "$SYSDIR" "mspaint.exe" ${StdUtils.Const.ShellVerb.PinToTaskbar}
    DetailPrint "Result: $0"

    StrCmp "$0" "ok" 0 +3
    MessageBox MB_TOPMOST "Paint should have been pinned to Taskbar now!"
    Goto +2
    MessageBox MB_TOPMOST "Failed to pin, see log for details!"
SectionEnd

Section
    DetailPrint "Going to un-pin MSPaint..."
    ${StdUtils.InvokeShellVerb} $0 "$SYSDIR" "mspaint.exe" ${StdUtils.Const.ShellVerb.UnpinFromTaskbar}
    DetailPrint "Result: $0"

    StrCmp "$0" "ok" 0 +3
    MessageBox MB_TOPMOST "Paint should have been un-pinned from Taskbar now!"
    Goto +2
    MessageBox MB_TOPMOST "Failed to un-pin, see log for details!"
SectionEnd