VBA：下標超出范圍

Question

有人問過類似的問題，但我想我有一個不同的問題：

 Workbooks.Open Filename:=filepath & "PLT.xlsx"

Worksheets("Sheet1").Range(Worksheets("Sheet1").Range("A1:B1"), Worksheets("Sheet1").Range("A1:B1").End(xlDown)).Copy
Windows("XXX.xslm").Activate
w1.Range("A4").PasteSpecial Paste:=xlPasteValues

第二行是問題。 實際上，它不會復制我想要的單元格。 當我打開該工作簿時，將選擇整個工作表。

我不明白為什么會收到該錯誤。

Answer 1

讓人驚訝。 如果要將值復制到它的簡單方法：

Global fso As New FileSystemObject

Public Sub CopyValuesTest()

    ' Get references to the files
    Dim wb1 As Workbook, wb2 As Workbook
    Set wb1 = Workbooks.Open(fso.BuildPath(filepath, "PLT.xlsx"))
    Set wb2 = Workbooks("XXX")

    ' Get references to the sheets
    Dim ws1 As Worksheet, ws2 As Worksheet
    Set ws1 = wb1.Sheets("Sheet1")
    Set ws2 = wb2.Sheets("Sheet1")

    ' Count non-empty rows under A1. Use 2 columns
    Dim N As Integer, M As Integer
    N = CountRows(ws1.Range("A1")): M = 2

    ' This copies the values
    ws2.Range("A4").Resize(N, M).Value = ws1.Range("A1").Resize(N, M).Value
End Sub

Public Function CountRows(ByRef r As Range) As Long
    If IsEmpty(r) Then
        CountRows = 0
    ElseIf IsEmpty(r.Offset(1, 0)) Then
        CountRows = 1
    Else
        CountRows = r.Worksheet.Range(r, r.End(xlDown)).Rows.Count
    End If
End Function

並確保定義了文件filepath 。 有關使用FileSystemObject請參見https://stackoverflow.com/a/5798392/380384