[英]Aggregate multiple nodes to a single node in XSLT
這是我需要使用XSLT轉換的XML源
<?xml version="1.0" encoding="UTF-8"?>
<tns:Grand_Parent_XML xmlns:tns="">
<GrandParent>
<Parent>
<Child>
<Age>3</Age>
</Child>
<Child>
<Gender>Male</Gender>
</Child>
<Child>
<Name>Todd</Name>
</Child>
<Other>1234</Other>
</Parent>
</GrandParent>
</tns:Grand_Parent_XML>
這是通過XSLT轉換后的所需輸出
<?xml version="1.0" encoding="UTF-8"?>
<tns:Grand_Parent_XML xmlns:tns="">
<GrandParent>
<Parent>
<Child>
<Age>3</Age>
<Gender>Male</Gender>
<Name>Todd</Name>
</Child>
<Other>1234</Other>
</Parent>
</GrandParent>
</tns:Grand_Parent_XML>
這是實際發生的事情...
<?xml version="1.0" encoding="UTF-8"?>
<tns:Grand_Parent_XML xmlns:tns="">
<GrandParent>
<Child>
<Age>3</Age>
<Gender>Male</Gender>
<Name>Todd</Name>
</Child>
</GrandParent>
</tns:Grand_Parent_XML>
我正在使用這個XSLT ...
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ns="">
<xsl:template match="Grand_Parent_XML/GrandParent/Parent">
<Child>
<xsl:for-each select="Child">
<xsl:if test="Age !=''">
<Age><xsl:value-of select="Age"/></Age>
</xsl:if>
<xsl:if test="Gender !=''">
<Gender><xsl:value-of select="Gender"/></Gender>
</xsl:if>
<xsl:if test="Name !=''">
<Name><xsl:value-of select="Nanme"/></Name>
</xsl:if>
</xsl:for-each>
</Child>
</xsl:template>
</xsl:stylesheet>
到目前為止,我對XSLT的掌握很少,我將不勝感激。 使用我創建的XSLT,Parent會被Child覆蓋,事實並非如此。 同樣,父級的其他子節點(即“其他”)也將被刪除。 我使用的實際XML字段比我在此處包含的字段多得多。 我可以選擇手動將所有節點包括在XSLT中,但是我覺得有一種更有效的方法。 謝謝!
這是一種通用方法,應適用於各種不同的輸入:
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>
<xsl:strip-space elements="*" />
<xsl:key name="kNamedSiblings" match="*"
use="concat(generate-id(..), '+', name())"/>
<xsl:template match="*">
<xsl:copy>
<xsl:apply-templates select="key('kNamedSiblings',
concat(generate-id(..), '+', name())
)/node()" />
</xsl:copy>
</xsl:template>
<xsl:template match="*[not(*) and . = '']" />
<xsl:template match="*[generate-id() !=
generate-id(key('kNamedSiblings',
concat(generate-id(..), '+', name()))[1]
)]" />
</xsl:stylesheet>
在樣本輸入上運行時,結果為:
<tns:Grand_Parent_XML xmlns:tns="...">
<GrandParent>
<Parent>
<Child>
<Age>3</Age>
<Gender>Male</Gender>
<Name>Todd</Name>
</Child>
<Other>1234</Other>
</Parent>
</GrandParent>
</tns:Grand_Parent_XML>
嘗試這種方式:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>
<!-- identity transform -->
<xsl:template match="@*|node()">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
<xsl:template match="Parent">
<xsl:copy>
<Child>
<xsl:apply-templates select="Child/*"/>
</Child>
<xsl:apply-templates select="*[not(self::Child)]"/>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
或者,如果您願意:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>
<!-- identity transform -->
<xsl:template match="@*|node()">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
</xsl:copy>
</xsl:template>
<xsl:template match="Parent">
<xsl:copy>
<xsl:apply-templates select="@*|node()"/>
<Child>
<xsl:apply-templates select="Child/*"/>
</Child>
</xsl:copy>
</xsl:template>
<xsl:template match="Child"/>
</xsl:stylesheet>
聲明:本站的技術帖子網頁,遵循CC BY-SA 4.0協議,如果您需要轉載,請注明本站網址或者原文地址。任何問題請咨詢:yoyou2525@163.com.