[英]How to get Full Name of current user in Delphi Win64
我已經做了很多搜索,並且在Stackoverflow上找到了一些有用的技巧來獲取用戶名和計算機名-甚至我發現 Norrit在Delphipages上發布的代碼完全可以滿足我的要求-除了在Win64目標平台上運行它時,獲取全名不起作用-它返回一個空字符串。 它在運行Win32版本時返回全名。
GetCurrentUser和GetDomainServerName函數可在Win32和Win64中使用。
谷歌搜索“delphi netusergetinfo”會帶來很多超過10年的結果 - 甚至在Delphi使用Win64之前。 它還提出了一個專家交流答案,鏈接到一些我在上面的一些lanman示例代碼,所以我有點卡在那里。
有沒有人知道我必須做什么改變才能讓GetDomainFullName在Win64下運行 - 或者是否有人有替代代碼我可以用來獲取當前登錄用戶的全名?
鏈接腐爛時,如下所示的完整代碼。
unit NetAPI32;
interface
uses
Windows, SysUtils;
function GetCurrentUser(): String;
function GetDomainServerName(): String;
function GetDomainFullName(ServerName, UserName: String): String;
implementation
function NetUserGetInfo(ServerName, UserName: PWideChar; Level: DWORD; var Buffer: Pointer): DWORD; stdcall; external 'netapi32.dll' name 'NetUserGetInfo';
function NetApiBufferFree(Buffer: pointer): DWORD; stdcall; external 'netapi32.dll' name 'NetApiBufferFree';
function NetWkstaUserGetInfo(ServerName: PWideChar; Level: DWORD; var Buffer: Pointer): Longint; stdcall; external 'netapi32.dll' name 'NetWkstaUserGetInfo';
type
TUserInfo1 = packed record
UserName: PWideChar;
DomainName : PWideChar;
OtherDomainNames: PWideChar;
ServerName: PWideChar;
end;
PUserInfo1 = ^TUserInfo1;
TUserInfo2 = packed record
Name: PWideChar;
Password: PWideChar;
PasswordAge: DWORD;
Priv: DWORD;
HomeDir: PWideChar;
Comment: PWideChar;
Flags: DWORD;
ScriptPath: PWideChar;
AuthorFlags: DWORD;
FullName: PWideChar;
UserComment: PWideChar;
Params: PWideChar;
WorkStations: PWideChar;
LastLogon: DWORD;
LastLogoff: DWORD;
AccountExpires: DWORD;
MaxStorage: DWORD;
UnitsPerWeek: DWORD;
LogonHours: DWORD;
BadPasswordCount: DWORD;
LogonCount: DWORD;
Server: PWideChar;
CountryCode: DWORD;
Codepage: DWORD;
end;
PUserInfo2 = ^TUserInfo2;
function GetCurrentUser(): String;
var
username: String;
size: DWORD;
begin
size := 255;
SetLength(username, size) ;
if GetUserName(PChar(username), size) then
Result := Copy(username, 1, size - 1)
else
Result := '';
end;
function GetDomainServerName(): String;
var
PUI1: PUserInfo1;
begin
Result := '';
if NetWkstaUserGetInfo(nil, 1, Pointer(PUI1)) = 0 then
begin
try
Result := WideCharToString(PUI1^.ServerName);
finally
NetApiBufferFree(PUI1);
end;
end;
end;
function GetDomainFullName(ServerName, UserName: String): String;
var
PUI2: PUserInfo2;
begin
Result := '';
if NetUserGetInfo(PWideChar(WideString(ServerName)), PWideChar(WideString(UserName)), 2, Pointer(PUI2)) = 0 then
try
Result := WideString(PUI2^.FullName);
finally
NetApiBufferFree(PUI2);
end;
end;
end.
如何使用示例:
ShowMessage(GetDomainFullName(GetDomainServerName(), GetCurrentUser()));
在Windows 2012 R2上運行的Delphi XE6
使用packed
是錯誤的,並且始終是錯誤的。 你剛剛離開它,因為它發生了32位的布局與對齊的相同。
從struct聲明中刪除packed
修飾符,您的代碼將起作用。
由於您已移至Unicode Delphi,因此現在可以停止使用WideString
。
function GetDomainFullName(const ServerName, UserName: string): string;
var
PUI2: PUserInfo2;
begin
if NetUserGetInfo(PChar(ServerName), PChar(UserName), 2, Pointer(PUI2)) = 0 then
try
Result := PUI2^.FullName;
finally
NetApiBufferFree(PUI2);
end
else
Result := '';
end;
聲明:本站的技術帖子網頁,遵循CC BY-SA 4.0協議,如果您需要轉載,請注明本站網址或者原文地址。任何問題請咨詢:yoyou2525@163.com.