[英]On error along with message box in VBA
在我的一個代碼中,如果我收到錯誤,我需要彈出文件名錯誤,然后繼續下一步.Below是我試圖使用的代碼片段,但它給了我錯誤。 誰能幫我
sourcefilename = File_list.Cells(i + 1, 1)
Set Baccha_Wbk = Wbk.Workbooks.Open(sourcefilename)
On Error GoTo ErrMsg
ErrMsg: MsgBox ("Error in file" & sourcefilename ),On Error Resume Next
另一種方法......
Sub Sample()
Dim sFile As String
'~~> If you are doing this in Excel. then you don't need Wbk
Dim Wbk As Excel.Application
Dim Baccha_Wbk As Workbook
Dim i As Long
On Error GoTo Whoa
'
'~~> Rest of the Code
'
sFile = File_list.Cells(i + 1, 1)
If FileFolderExists(sFile) Then
'~~> If you are doing this in Excel. then you don't need Wbk
Set Baccha_Wbk = Wbk.Workbooks.Open(sFile)
Else
MsgBox "File Doesn't exists"
End If
Exit Sub
Whoa:
MsgBox Err.Description
End Sub
Public Function FileFolderExists(strFullPath As String) As Boolean
On Error GoTo EarlyExit
If Not Dir(strFullPath, vbDirectory) = vbNullString Then FileFolderExists = True
EarlyExit:
On Error GoTo 0
End Function
你快到了。 這是你如何做到的:
sourcefilename = File_list.Cells(i + 1, 1)
On Error Resume Next 'Errors get swallowed without warning. Use sparingly.
Set Baccha_Wbk = Wbk.Workbooks.Open(sourcefilename)
If Err.Number <> 0 Then MsgBox ("Error in file" & sourcefilename )
On Error Goto 0 'Back to normal: errors get thrown as usual
更完整的錯誤處理程序可能如下所示:
Sub abcd()
On Error GoTo ErrorHandler
'[code...]
sourcefilename = File_list.Cells(i + 1, 1)
Set Baccha_Wbk = Wbk.Workbooks.Open(sourcefilename)
'[more code...]
ExitProcedure:
On Error Resume Next
'Clean-up code goes here
Exit Sub
ErrorHandler:
Select Case Err.Number
'Deal with each of the expected errors
Case 53 ' File not found
MsgBox "File not found: " & sourcefilename
Case 70 ' Permission denied
MsgBox "Permission denied. Maybe you don't have permission to access this drive? " & sourcefilename
'etc. etc.
'Deal with unexpected errors
Case Else
UnexpectedError Err.Number, Err.Source & ", Procedure abcd of Module Module1", Err.Description, Err.HelpFile, Err.HelpContext
End Select
Resume ExitProcedure
Resume
End Sub
( 為什么雙重Resume
到底? )
隨着這個助手子自定義你喜歡。
Public Sub UnexpectedError(ByVal lngNumber As Long, _
ByVal strSource As String, ByVal strDescription As String, _
ByVal strHelpfile As String, ByVal lngHelpContext As Long)
On Error Resume Next
MsgBox "[" & strSource & "]" & vbCrLf & "Run-time error '" _
& CStr(lngNumber) & "':" _
& vbCrLf & vbCrLf & strDescription, vbExclamation, Application.Name, _
strHelpfile, lngHelpContext
Application.EnableEvents = True
Debug.Print "Case " & CStr(lngNumber) & " '" & strDescription
'Debug.Assert False 'uncomment while developing
End Sub
聲明:本站的技術帖子網頁,遵循CC BY-SA 4.0協議,如果您需要轉載,請注明本站網址或者原文地址。任何問題請咨詢:yoyou2525@163.com.