XSLT：拆分和合並XML元素

Question

我是XSLT編程的初學者。 我已經完成了轉換以下xml的任務：

<Test>TestA::test1</Test>
<Test>TestA::test2</Test>
<Test>TestB::test3</Test>
<Test>TestB::test4</Test>

輸出xml如下所示：

<Class id="TestA">
    <Method id="test1"/>
    <Method id="test2"/>
</Class>
<Class id="TestB">
    <Method id="test3"/>
    <Method id="test4"/>
</Class>

輸入的xml包含C ++風格的CppUnit測試用例的名稱（模式Class :: Method）。 我嘗試了許多不同的方法，並且閱讀了無數的stackoverflow異常，但是找不到解決方案。

我必須使用XSLT 1.0解決問題。

在此先感謝，mexl

Answer 1

這基本上是一個分組問題，需要通過（非常輕微）扭曲的Muenchian分組 （在XSLT 1.0中）解決。 但是，首先，您的輸入必須具有根元素-否則，它不是XML文檔：

<root>
    <Test>TestA::test1</Test>
    <Test>TestA::test2</Test>
    <Test>TestB::test3</Test>
    <Test>TestB::test4</Test>
</root>

完成后，以下樣式表：

XSLT 1.0

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:key name="k" match="Test" use="substring-before(., '::')" />

<xsl:template match="/">
    <output>
        <xsl:for-each select="root/Test[count(. | key('k', substring-before(., '::'))[1]) = 1]">
            <Class id="{substring-before(., '::')}">
                <xsl:for-each select="key('k', substring-before(., '::'))">
                     <Method id="{substring-after(., '::')}"/>
                </xsl:for-each>
            </Class>
        </xsl:for-each>
    </output>
</xsl:template>

</xsl:stylesheet>

將返回：

<?xml version="1.0" encoding="UTF-8"?>
<output>
   <Class id="TestA">
      <Method id="test1"/>
      <Method id="test2"/>
   </Class>
   <Class id="TestB">
      <Method id="test3"/>
      <Method id="test4"/>
   </Class>
</output>

Answer 2

結合使用xsl:key / generate-id ， substring-before /substring-after ，如下所示：

特定

<Tests>
  <Test>TestA::test1</Test>
  <Test>TestA::test2</Test>
  <Test>TestB::test3</Test>
  <Test>TestB::test4</Test>
</Tests>

使用此模板：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output indent="yes" method="xml" encoding="UTF-8"/>

<xsl:key name="testClassKey" match="Test" use="substring-before(., '::')"/>

<xsl:template match="Test" mode="asMethod">
  <xsl:variable name="methodId" select="substring-after(., '::')" />

  <Method id="{$methodId}" />
</xsl:template>


<xsl:template match="Test">
  <xsl:variable name="thisTest" select="." />
  <xsl:variable name="classId" select="substring-before(., '::')" />

  <Class id="{$classId}">
    <xsl:apply-templates select="//Test[substring-before(., '::') = $classId]" mode="asMethod"/>
  </Class>
</xsl:template>


<xsl:template match="Tests">
  <TestClasses>
    <xsl:apply-templates select="Test[generate-id(.) = generate-id(key('testClassKey', substring-before(., '::'))[1])]" />
  </TestClasses>
</xsl:template>
</xsl:stylesheet>

要獲得此結果：

<?xml version="1.0" encoding="UTF-8"?>
<TestClasses>
  <Class id="TestA">
    <Method id="test1" />
    <Method id="test2" />
  </Class>
  <Class id="TestB">
    <Method id="test3" />
    <Method id="test4" />
  </Class>
</TestClasses>