Android Gradle構建錯誤

Question

我在build.gradle文件中添加依賴項。

我的代碼是：

dependencies {
compile fileTree(dir: 'libs', include: ['*.jar'])
compile 'com.android.support:appcompat-v7:21.0.3'
compile 'com.google.android.gms:play-services:6.1.11'
compile 'org.apache.httpcomponents:httpmime:4.4.1'
compile 'org.apache.httpcomponents:httpcore:4.4.1'
compile 'org.apache.httpcomponents:httpclient:4.4.1'

}

我收到了錯誤：

Warning:Dependency org.apache.httpcomponents:httpclient:4.4.1 is ignored for debug as it may be conflicting with the internal version provided by Android.
     In case of problem, please repackage it with jarjar to change the class packages

Warning:Dependency org.apache.httpcomponents:httpclient:4.4.1 is ignored for debug as it may be conflicting with the internal version provided by Android.
     In case of problem, please repackage it with jarjar to change the class packages

Warning:Dependency org.apache.httpcomponents:httpclient:4.4.1 is ignored for release as it may be conflicting with the internal version provided by Android.
     In case of problem, please repackage it with jarjar to change the class packages

Warning:Dependency org.apache.httpcomponents:httpclient:4.4.1 is ignored for release as it may be conflicting with the internal version provided by Android.
     In case of problem, please repackage it with jarjar to change the class packages

如何解決這個問題呢。 請幫我 ？

Answer 1

您可以嘗試在build.gradle（Module：app）中添加它。 它解決了我的問題：

packagingOptions{
    exclude 'META-INF/DEPENDENCIES'
    exclude 'META-INF/NOTICE'
    exclude 'META-INF/LICENSE'
}

我的最終構建gradle看起來像：

apply plugin: 'com.android.application'

android {
    compileSdkVersion 21
    buildToolsVersion "21.1.2"

    defaultConfig {
        applicationId "info.androidhive.camerafileupload"
        minSdkVersion 19
        targetSdkVersion 21
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.txt'
        }
    }
    packagingOptions{
        exclude 'META-INF/DEPENDENCIES'
        exclude 'META-INF/NOTICE'
        exclude 'META-INF/LICENSE'
    }
}

dependencies {
    compile 'com.android.support:appcompat-v7:21.0.3'
    compile files('libs/httpclient-4.3.6.jar')
    compile files('libs/httpcore-4.3.3.jar')
    compile files('libs/httpmime-4.3.6.jar')
}

注意：在我的情況下，我已經在我的libs文件夾中粘貼了這3個罐子。 您可以下載並執行此操作。

Answer 2

我通過替換以下行解決了這個問題

compile "org.apache.httpcomponents:httpclient:4.4.1"

有了這個

compile "org.apache.httpcomponents:httpclient-android:4.3.5.1"

如果您想了解有關HttpClient for Android的更多信息，請訪問以下網址

https://hc.apache.org/httpcomponents-client-4.3.x/android-port.html

Answer 3

如果你的compileSdkVersion是19（在我的情況下）我用這個來解決問題

compile ('org.apache.httpcomponents:httpmime:4.3'){
    exclude group: 'org.apache.httpcomponents', module: 'httpclient'
}
compile ('org.apache.httpcomponents:httpcore:4.4.1'){
    exclude group: 'org.apache.httpcomponents', module: 'httpclient'
}
compile 'commons-io:commons-io:1.3.2'

否則，如果您的compileSdkVersion為23則使用

android {
useLibrary 'org.apache.http.legacy'
packagingOptions {
    exclude 'META-INF/DEPENDENCIES'
    exclude 'META-INF/NOTICE'
    exclude 'META-INF/LICENSE'
    exclude 'META-INF/LICENSE.txt'
    exclude 'META-INF/NOTICE.txt'
    }
}

Answer 4

您可以為所有庫添加以下配置，而不是向每個庫添加exclude ：

configurations {
    all*.exclude group: 'org.apache.httpcomponents',module: 'httpclient'
}

Answer 5

如果沒有什么可以嘗試這個。無限期地工作

替換這個

 dependencies {
......
.......
    compile 'org.apache.httpcomponents:httpclient:4.4.1'
}

使用以下代碼

dependencies {
    compile group: 'org.apache.httpcomponents' , name: 'httpclient-android' , version: '4.3.5.1'
}