Gradle：在已發布的 dist.zip 的 /lib 文件夾中添加 sources.jar 文件以及我的所有其他依賴項

Question

我有一個使用 gradle 構建的 java 項目。 我正在為我的項目發布一個 dist.zip 文件夾，我想將我的項目的 sources.jar 添加到 dist.zip 中的 /lib 子文件夾。 我可以創建一個 sources.jar 文件和我的 dist.zip 文件，但我不確定如何在 dist.zip 中添加 sources.jar。 我怎樣才能做到這一點？ 我嘗試在創建后將 .jar 復制到 /lib 文件夾中，但我無法讓它工作。 下面是我的 gradle.build 腳本中的發布和 sourcesJar 任務。

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

publishing {

    repositories {  
        maven {
            url 'localfolder'
        }
    }

    publications {

        maven(MavenPublication) {
            groupId 'ca.project'
            artifactId applicationName
            version version

            from components.java

            artifact sourcesJar {
                classifier "sources"
            }

            artifact distZip {
                classifier "dist"
            }
        }

    }
}

Answer 1

您需要告訴應用程序插件在發行版中包含您的sourcesJar任務的輸出：

distributions {
    main {
        contents {
            from sourcesJar
        }
    }
}

這會將它放在根目錄中，如果你想要它在其他地方，你可以這樣做：

distributions {
    main {
        contents {
            from(sourcesJar) {
                into "lib"
            }
        }
    }
}