在批處理文件中的if語句中調用python函數時出現奇怪的行為

Question

大家。

我正在嘗試從批處理文件中調用python函數，尤其是在if語句內部（我正在使用python 3.3.2）。 假設我在getFileRevision.py中有兩個變量％filePath％和％filePath2％和一個python函數。 這是我的批處理腳本的一部分：

python getFileRevision.py %filePath%
set revision=%ERRORLEVEL%

python getFileRevision.py %filePath2%
set revision2=%ERRORLEVEL%

echo Before entering if statement:
echo revision=%revision%
echo revision2=%revision2%

python getFileRevision.py %filePath%
set revision=%ERRORLEVEL%

if exist %filePath2% (
    echo condition = true!
    python getFileRevision.py %filePath2%
    set revision2=%ERRORLEVEL%
)

echo revision=%revision%
echo revision2=%revision2%

我為兩個不同的參數調用python函數，並輸出返回值。 然后再做一次，但是這次我在If語句中調用python函數。 這是控制台中的打印內容：

    revision=109803
    revision2=109671
    condition = true!
    revision=109803
    revision2=109803

從這個結果中，您可以看到在If語句中調用python函數並沒有改變返回值。 有人知道這種奇怪行為的原因以及如何解決嗎？

不管怎么說，還是要謝謝你。

Answer 1

在代碼塊內（括號內的任何代碼），您不能使用'％'來訪問最新的變量值。 您需要enabledelayedexpansion並使用! 代替。

setlocal enabledelayedexpansion
python getFileRevision.py %filePath%
set revision=%ERRORLEVEL%

python getFileRevision.py %filePath2%
set revision2=%ERRORLEVEL%

echo Before entering if statement:
echo revision=%revision%
echo revision2=%revision2%

python getFileRevision.py %filePath%
set revision=%ERRORLEVEL%

if exist %filePath2% (
    echo condition = true!
    python getFileRevision.py %filePath2%
    set revision2=!ERRORLEVEL!
)

echo revision=%revision%
echo revision2=%revision2%

現在應該可以正常工作了。