是否可以使用批處理文件打開一個新的cmd窗口，並將其用作實時日志？

Question

我創建了一個批處理文件，以幫助我為手機上的應用程序編寫腳本，該腳本將自動執行觸摸任務。 我正在創建的腳本將需要240x9行的腳本語言來完成我想完成的任務，有沒有辦法打開新的cmd行並將文本輸出到新窗口？

因此，例如，現在我可以在批處理文件中使用每個選項來編寫腳本語言所需的屏幕觸摸坐標，以將我的任務執行到這樣的文本文件中。

@ECHO :start>speedsearch.txt

是否可以將它們傳遞到新窗口中以用作實時日志，所以如果我放開我的位置，可以參考日志窗口來提醒自己創建腳本的位置嗎？

我確實知道，如果要使用常規cmd窗口。

TYPE C:\speedSearch.txt

它會打印文本文件中的內容，因此無論如何都可以將命令從批處理腳本傳遞到該文件。

TYPE C:\speedSearch.txt

每次我選擇一個選項向文件中的腳本添加一行時？ 我已經在腳本的開頭使用了新的窗口。

start "LOGGING WINDOW" C:\WINDOWS\SYSTEM32\CMD.EXE

我只需要一些如何將命令傳遞到新窗口的幫助，而不會破壞批處理腳本中的當前會話。

Answer 1

這個問題是關於同步的 。 有幾種方法可以在批處理文件中啟動兩個或多個執行線程，並且存在幾種解決通常的同步問題的標准方法。 這種情況下的區別在於，第二個線程是通過start命令start ，因此無法重定向其標准輸入。 准確檢測第二個線程中文件結尾的唯一方法是插入一個指示該點的特定行；否則，請執行以下操作。 在下面的代碼中，“：EOF”字符串用於此目的。

@echo off
setlocal EnableDelayedExpansion

if "%~1" neq "" goto %1

echo :start> speedsearch.txt
rem Run View Log code simultaneously with Main code
start "View Log" "%~NX0" ViewLog

:Main
   set "line="
   set /P "line=Enter next line: "
   if not defined line goto endMain
   echo %line%>> speedsearch.txt
goto Main
:endMain
rem Send the "end of file" mark
echo :EOF>> speedsearch.txt
echo File complete
goto :EOF


:ViewLog
set i=0
call :Update < speedsearch.txt 
goto :EOF

:Update
   set "line="
   set /P "line="
   if "!line!" equ ":EOF" goto :EOF
   if defined line (
      set /A i+=1
      echo !i!- !line!
   )
goto :Update