[英]SOAPUI Groovy script inserting xml node with custom value
因此,我采取了一些步驟,需要一些數字id並在數據庫中查找它們的值。 我希望能夠編輯響應xml並包括從數據庫中獲取的值,以提高可讀性。
我想出了如何將xml節點添加到xmlHolder中,但是我似乎無法在該節點內放置值。
這是最接近的“看似”工作代碼:
def groovyUtils = new com.eviware.soapui.support.GroovyUtils(context)
def dbResult = testRunner.testCase.testSteps["getNames"].getResponseContent()
def xmlOfferNames = groovyUtils.getXmlHolder(dbResult)
def names = xmlOfferNames.getNodeValues("//NAME")
def codes = xmlOfferNames.getNodeValues("//ID")
def recs = groovyUtils.getXmlHolder("Item#Reply")
def insert
for(int i=0; i<names.size(); i++){
for(node in recs.getDomNodes("//Item[ID='"+codes[i]+"']")){
//insert = '<NAME>'+names[i]+'</NAME>' //nothing is taking strings
//node.appendNode(new Node(node, 'NAME', names[i])) //dne constructor
insert = node.getOwnerDocument().createElementNS(node.getNamespaceURI(), "NAME")
//log.info names[i]
insert.setNodeValue(names[i])
//log.info insert.metaClass.methods*.name.sort().unique()
node.insertBefore(insert , node.getFirstChild())
}
}
recs.updateProperty()
log.info recs.getXml()
但是,當它打印出生成的xml時,我只有空的<NAME/>
標記,沒有任何值。
我嘗試使用insert.setTextContent()
但是它說java.long.RuntimeException: DOM Level 3 Not implemented
。 我看不到其他可用來設置值的東西。
(半相關,奇怪的是,它也不會在我的步驟中更新xml,但我尚未開始進行研究)
可以使用XmlSlurper
來代替使用holder
來修改XML
:
import groovy.xml.XmlUtil
def xml = '''<sample>
<RetailRecommendation>
<OfferCode>a1</OfferCode>
</RetailRecommendation>
<RetailRecommendation>
<OfferCode>b2</OfferCode>
</RetailRecommendation>
<RetailRecommendation>
<OfferCode>a1</OfferCode>
<OfferCode>ac3</OfferCode>
</RetailRecommendation>
</sample>
'''
def recs = new XmlSlurper().parseText(xml)
def names = ['kilo','mega','giga']
def codes = ['a1','b2','ac3']
// for each name
names.eachWithIndex{ name, i ->
// find all OfferCode elements inside RetailRecommendation
// where value is in codes[i] array
recs.RetailRecommendation.'**'.findAll { node ->
node.name() == 'OfferCode' && node.text() == codes[i]
}.each{ elem -> // for each element...
// create the new node to add
def nodeToAdd = new XmlSlurper().parseText('<OFFER_NAME>' + name + '</OFFER_NAME>')
// and append the node to your element
elem.parent().appendNode(nodeToAdd)
}
}
log.info XmlUtil.serialize(recs)
結果是:
<sample>
<RetailRecommendation>
<OfferCode>a1</OfferCode>
<OFFER_NAME>kilo</OFFER_NAME>
</RetailRecommendation>
<RetailRecommendation>
<OfferCode>b2</OfferCode>
<OFFER_NAME>mega</OFFER_NAME>
</RetailRecommendation>
<RetailRecommendation>
<OfferCode>a1</OfferCode>
<OfferCode>ac3</OfferCode>
<OFFER_NAME>kilo</OFFER_NAME>
<OFFER_NAME>giga</OFFER_NAME>
</RetailRecommendation>
</sample>
在您的代碼內部,您可以繼續使用holder
獲取names
和codes
但更改修改響應的方式,總的來說可能是這樣的:
import groovy.xml.XmlUtil
def groovyUtils = new com.eviware.soapui.support.GroovyUtils(context)
def dbResult = testRunner.testCase.testSteps["getOfferNames"].getResponseContent()
def xmlOfferNames = groovyUtils.getXmlHolder(dbResult)
def names = xmlOfferNames.getNodeValues("//NAME")
def codes = xmlOfferNames.getNodeValues("//OFFERCODE1")
def recs = new XmlSlurper().parseText(context.expand('${getRetailRecommendation#Response}'))
// for each name
names.eachWithIndex{ name, i ->
// find all OfferCode elements inside RetailRecommendation
// where value is in codes[i] array
recs.RetailRecommendation.'**'.findAll { node ->
node.name() == 'OfferCode' && node.text() == codes[i]
}.each{ elem ->
// for each node found it
def nodeToAdd = new XmlSlurper().parseText('<OFFER_NAME>' + name + '</OFFER_NAME>')
elem.parent().appendNode(nodeToAdd)
}
}
log.info XmlUtil.serialize(recs)
希望這可以幫助,
事實證明,您不能只向元素添加字符串,而必須創建一個文本節點。
insert.appendChild(node.getOwnerDocument().createTextNode(names[i]))
聲明:本站的技術帖子網頁,遵循CC BY-SA 4.0協議,如果您需要轉載,請注明本站網址或者原文地址。任何問題請咨詢:yoyou2525@163.com.