從awk的多個特定列中減去單個最大數

Question

我有一個逗號分隔的文件，看起來像

R,F,TE,K,G,R
1,0,12,f,1,18
2,1,17,t, ,17
3,1,  , ,1,
4,0,15, ,0,16

有些項目丟失了，第一行是我要忽略的標題。 我想計算特定列中的第二個最小數字，並從該列中的所有元素中減去它，除非該列中的值為最小值。 在此示例中，我想從示例中的第3列和第6列中減去第二個最小值。 因此，我的最終值為：

R,F,TE,K,G,R
1,0,12,f,1,1
2,1, 2,t, ,0
3,1, , ,0,
4,0, 0, ,0,16

我嘗試單獨使用單列並提供手動編碼的閾值，以使其達到第二大

awk 'BEGIN {FS=OFS=","; 
};
{ min=1000000; 
 if($3<min && $3 != "" && $3>12) min = $3; 
 if($3>0) $3 = $3-min+1;
 print}
 END{print min}
 ' try1.txt

它找到最小的正確值，但輸出不符合預期。 在awk中應該有一種更簡單的方法。

Answer 1

我要遍歷文件兩次，一次是找到最小值，一次是調整值。 這是時間與內存的權衡。

awk -F, -v OFS=, '
    NR == 1    {min3 = $3; min6 = $6} 
    NR == FNR  {if ($3 < min3) min3 = $3; if ($6 < min6) min6 = $6; next}
    $3 != min3 {$3 -= min3}
    $6 != min6 {$6 -= min6}
    {print}
' try1.txt try1.txt

對於更漂亮的輸出：

awk -F, -v OFS=, '
    NR == 1    {min3 = $3; min6 = $6; next}
    NR == FNR  {if ($3 < min3) min3 = $3; if ($6 < min6) min6 = $6; next}
    FNR == 1   {len3 = length("" min3); len6 = length("" min6)}
    $3 != min3 {$3 = sprintf("%*d", len3, $3-min3)}
    $6 != min6 {$6 = sprintf("%*d", len6, $6-min6)}
    {print}
' try1.txt try1.txt

---

鑒於新的要求：

min2_3=$(cut -d, -f3 try1.txt | tail -n +2 | sort -n | grep -v '^ *$' | sed -n '2p')
min2_6=$(cut -d, -f6 try1.txt | tail -n +2 | sort -n | grep -v '^ *$' | sed -n '2p')

awk -F, -v OFS=, -v min2_3=$min2_3 -v min2_6=$min2_6 '
    NR==1 {print; next}
    $3 !~ /^ *$/ && $3 >= min2_3 {$3 -= min2_3}
    $6 !~ /^ *$/ && $6 >= min2_6 {$6 -= min2_6}
    {print}
' try1.txt

R,F,TE,K,G,R
1,0,12,f,1,1
2,1,2,t, ,0
3,1,  , ,1,
4,0,0, ,0,16

Answer 2

BEGIN{
    FS=OFS=","
}
{
    if(NR==1){print;next}
    if(+$3)a[NR]=$3
    if(+$6)b[NR]=$6
    s[NR]=$0
}
END{
    asort(a,c)
    asort(b,d)
    for(i=2;i<=NR;i++){
        split(s[i],t)
        if(t[3]!=c[1]&&+t[3]!=0)t[3]=t[3]-c[2]
        if(t[6]!=d[1]&&+t[6]!=0)t[6]=t[6]-d[2]
        print t[1],t[2],t[3],t[4],t[5],t[6]
    }
}