UIImage cv ::使用alpha通道進行Mat轉換

Question

我正在使用以下代碼將UIImage*和cv::Mat轉換為彼此：

- (cv::Mat)cvMatFromUIImage:(UIImage *)image
{
  CGColorSpaceRef colorSpace = CGImageGetColorSpace(image.CGImage);
  CGFloat cols = image.size.width;
  CGFloat rows = image.size.height;

  cv::Mat cvMat(rows, cols, CV_8UC4); // 8 bits per component, 4 channels (color channels + alpha)

  CGContextRef contextRef = CGBitmapContextCreate(cvMat.data,                 // Pointer to  data
                                                 cols,                       // Width of bitmap
                                                 rows,                       // Height of bitmap
                                                 8,                          // Bits per component
                                                 cvMat.step[0],              // Bytes per row
                                                 colorSpace,                 // Colorspace
                                                 kCGImageAlphaNoneSkipLast |
                                                 kCGBitmapByteOrderDefault); // Bitmap info flags

  CGContextDrawImage(contextRef, CGRectMake(0, 0, cols, rows), image.CGImage);
  CGContextRelease(contextRef);

  return cvMat;
}

和

-(UIImage *)UIImageFromCVMat:(cv::Mat)cvMat
{
  NSData *data = [NSData dataWithBytes:cvMat.data length:cvMat.elemSize()*cvMat.total()];
  CGColorSpaceRef colorSpace;

  if (cvMat.elemSize() == 1) {
      colorSpace = CGColorSpaceCreateDeviceGray();
  } else {
      colorSpace = CGColorSpaceCreateDeviceRGB();
  }

  CGDataProviderRef provider = CGDataProviderCreateWithCFData((__bridge CFDataRef)data);

  // Creating CGImage from cv::Mat
  CGImageRef imageRef = CGImageCreate(cvMat.cols,                                 //width
                                     cvMat.rows,                                 //height
                                     8,                                          //bits per component
                                     8 * cvMat.elemSize(),                       //bits per pixel
                                     cvMat.step[0],                            //bytesPerRow
                                     colorSpace,                                 //colorspace
                                     kCGImageAlphaNone|kCGBitmapByteOrderDefault,// bitmap info
                                     provider,                                   //CGDataProviderRef
                                     NULL,                                       //decode
                                     false,                                      //should interpolate
                                     kCGRenderingIntentDefault                   //intent
                                     );


  // Getting UIImage from CGImage
  UIImage *finalImage = [UIImage imageWithCGImage:imageRef];
  CGImageRelease(imageRef);
  CGDataProviderRelease(provider);
  CGColorSpaceRelease(colorSpace);

  return finalImage;
 }

我從OpenCV文檔中獲取了這些內容。 我用它們如下：

UIImage *img = [UIImage imageNamed:@"transparent.png"];
UIImage *img2 = [self UIImageFromCVMat:[self cvMatFromUIImage:img]];

但是，這些功能會丟失Alpha通道信息。 我知道這是因為標志kCGImageAlphaNone和kCGImageAlphaNoneSkipLast ，遺憾的是我找不到通過改變這些標志丟失alpha信息的方法。

那么，如何在不丟失alpha信息的情況下在彼此之間轉換這兩種類型呢？

這是我使用的圖像：

Answer 1

你需要不傳遞kCGImageAlphaNoneSkipLast而是傳遞(kCGBitmapByteOrder32Host | kCGImageAlphaPremultipliedFirst)以獲得BGRA格式的預乘alpha。 CoreGraphics僅支持預乘alpha。 但是，您需要檢查OpenCV如何以像素為單位表示alpha，以確定如何告訴OpenCV像素已經預乘。 我使用的代碼假設使用OpenCV直接alpha，所以你需要小心。

Answer 2

我們應該使用opencv v2.4.6中的這些函數：

UIImage* MatToUIImage(const cv::Mat& image);
void UIImageToMat(const UIImage* image, cv::Mat& m, bool alphaExist = false);

別忘了包括：

opencv2/imgcodecs/ios.h