需要執行XML輸入和XSL的輸出以創建XML輸出

Question

我已經編寫了以下xml代碼，它們將作為輸入，並轉到xslt腳本，該腳本將處理xml代碼以生成xml輸出：

XML輸入

<TAB512>
<WA>f1,f2</WA>
</TAB512>
<TAB512>
<WA>df1,df2</WA>
</TAB512>
</DATA>
<FIELDS>
<Filed>
<FIELDNAME>Field1</FIELDNAME>
</Filed>
<Filed>
<FIELDNAME>Field2</FIELDNAME>
</Filed>
</FIELDS>
</Response>

在第一元件<WA>為在第一元件的<FIELDNAME>在xsl腳本將格式化輸入XML生成XML輸出

<TAB512>
<WA>f1,f2</WA>
</TAB512>

我的意思是，'，'之前的第一個元素將用於Field1，而'，'之后的元素將用於Field2

XSL腳本

    <xsl:template name="WriteRecordNodeTemplate">
<xsl:param name="Field" />
<xsl:param name="WA" />

<Response>
<xsl:call-template name="StringSplit">
<xsl:with-param name="fi" select="$Field" />
<xsl:with-param name="w" select="$WA" />
</xsl:call-template>
</Response>
</xsl:template>

<xsl:template name="StringSplit">
<xsl:param name="fi" />
<xsl:param name="w" />
<xsl:choose>
  <xsl:when test="contains($w, ',')">
<Record>
   <xsl:value-of select="$fi" ><xsl:value-of select="substring-before($w, ',')" /></xsl:value-of select="$fi" >
</Record>

     <xsl:call-template name="StringSplit">
     <xsl:param name="fi" />
     <xsl:with-param name="w" select="substring-after($w, ',')" />
     </xsl:call-template>

  </xsl:when>
  <xsl:otherwise>
      <!-- if there is no more delimiter values, print out 
the whole string -->
<Record>
<xsl:value-of select="$fi" ><xsl:value-of select="$w" /></xsl:value-of select="$fi" >
</Record>
   </xsl:otherwise>
</xsl:choose>

</xsl:template>

最后

需要這樣的XML輸出：

<TableName>
<Record>
<Field1>f1</Field1>
<Field2>f2</Field2>
</Record>
<Record>
<Field1>df1</Field1>
<Field2>df2</Field2>
</Record>
</TableName>

Answer 1

我猜你想做：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:variable name="field-names" select="/Response/FIELDS/Filed" />

<xsl:template match="/Response">
    <TableName>
        <xsl:for-each select="DATA/TAB512">
            <Record>
                <xsl:call-template name="tokenize">
                    <xsl:with-param name="text" select="WA"/>
                </xsl:call-template>
            </Record>
        </xsl:for-each>
    </TableName>
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="','"/>
    <xsl:param name="i" select="1"/>
        <xsl:variable name="token" select="substring-before(concat($text, $delimiter), $delimiter)" />
        <xsl:if test="$token">
            <xsl:element name="{$field-names[$i]/FIELDNAME}">
                <xsl:value-of select="$token"/>
            </xsl:element>
        </xsl:if>
        <xsl:if test="contains($text, $delimiter)">
            <!-- recursive call -->
            <xsl:call-template name="tokenize">
                <xsl:with-param name="text" select="substring-after($text, $delimiter)"/>
                <xsl:with-param name="i" select="$i + 1"/>
            </xsl:call-template>
        </xsl:if>
</xsl:template>

</xsl:stylesheet>

應用於以下測試輸入：

M

<Response>
  <DATA>
    <TAB512>
      <WA>a1,b1</WA>
    </TAB512>
    <TAB512>
      <WA>a2,b2</WA>
    </TAB512>
  </DATA>
  <FIELDS>
    <Filed>
      <FIELDNAME>ColumnA</FIELDNAME>
    </Filed>
    <Filed>
      <FIELDNAME>ColumnB</FIELDNAME>
    </Filed>
  </FIELDS>
</Response>

結果將是：

<?xml version="1.0" encoding="UTF-8"?>
<TableName>
   <Record>
      <ColumnA>a1</ColumnA>
      <ColumnB>b1</ColumnB>
   </Record>
   <Record>
      <ColumnA>a2</ColumnA>
      <ColumnB>b2</ColumnB>
   </Record>
</TableName>

---

請注意，這要求FIELDNAME值是有效的XML名稱。 還假定每個WA元素具有與Filed節點數相同的逗號分隔值數。

還假定您輸入拼錯Filed所示的例子。