評論在 vim 曝光主題中有一個丑陋的背景顏色

Question

我的配置

iTerm2 - 使用 Solarized 主題，xterm-256color 作為Report terminal type 。

zsh - 主題設置為agnoster

Solarized vim - 我的 vim 主題已曝光，這是設置：

set background=dark
let g:solarized_termcolors=16 "This fixed some issues i had of bg colors that was coming brown before
colorscheme solarized

現在所有的顏色都按預期出現，期待具有深灰色背景顏色的丑陋評論（我認為這不是這個主題的默認值）

注意：我之前有過海洋主題，而評論顏色問題實際上是在更新我的 vundle 包之后發生的。

以下是我的 .vimrc 文件：

set nobackup          " get rid of anoying ~file
set encoding=utf-8

"Load up vundle
set nocompatible                  " don't need to be compatible with old vim
filetype off
set rtp+=~/.vim/bundle/Vundle.vim
call vundle#begin()

Plugin 'VundleVim/Vundle.vim'
Plugin 'mattn/emmet-vim'             " Emmet for html
Plugin 'evidens/vim-twig'            " Twig Syntax highlighting
Plugin 'hail2u/vim-css3-syntax'      " CSS3 Syntax
Plugin 'Solarized'
" Plugin 'mhartington/oceanic-next'    " Color Scheme

call vundle#end()
filetype plugin indent on
" load up pathogen and all bundles
" call pathogen#infect()
" call pathogen#helptags()

runtime macros/matchit.vim        " autoload that extends % functionality
syntax on                         " show syntax highlighting
set autoindent                    " set auto indent
set ts=2                          " set indent to 2 spaces
set shiftwidth=2
set softtabstop=2
set expandtab                     " use spaces, not tab characters
set relativenumber                " show relative line numbers
set showmatch                     " show bracket matches
set ignorecase                    " ignore case in search
set hlsearch                      " highlight all search matches
" set cursorline                    " highlight current line
set smartcase                     " pay attention to case when caps are used
set incsearch                     " show search results as I type
set ttimeoutlen=100               " decrease timeout for faster insert with 'O'
set vb                            " enable visual bell (disable audio bell)
set ruler                         " show row and column in footer
set scrolloff=2                   " minimum lines above/below cursor
set laststatus=2                  " always show status bar
set list listchars=tab:»·,trail:· " show extra space characters
set nofoldenable                  " disable code folding
set clipboard=unnamed             " use the system clipboard
set wildmenu                      " enable bash style tab completion
set wildmode=list:longest,full

" Color Scheme Settings
" set t_Co=256
set background=dark
let g:solarized_termcolors=16
colorscheme solarized
" set t_Co=256
" colorscheme OceanicNext
" set background=dark

" emmet key remap
imap <expr> <tab> emmet#expandAbbrIntelligent("\<tab>")
let g:cssColorVimDoNotMessMyUpdatetime = 1

" Current Directory remap
cnoremap <expr> %%  getcmdtype() == ':' ? expand('%:h').'/' :'%%'

" Set tabstop, softtabstop and shiftwidth to the same value
command! -nargs=* Stab call Stab()
function! Stab()
  let l:tabstop = 1 * input('set tabstop = softtabstop = shiftwidth = ')
  if l:tabstop > 0
    let &l:sts = l:tabstop
    let &l:ts = l:tabstop
    let &l:sw = l:tabstop
  endif
  call SummarizeTabs()
endfunction

function! SummarizeTabs()
  try
    echohl ModeMsg
    echon 'tabstop='.&l:ts
    echon ' shiftwidth='.&l:sw
    echon ' softtabstop='.&l:sts
    if &l:et
      echon ' expandtab'
    else
      echon ' noexpandtab'
    endif
  finally
    echohl None
  endtry
endfunction

if &term =~ '256color'
  " disable Background Color Erase (BCE) so that color schemes
  " render properly when inside 256-color tmux and GNU screen.
  set t_ut=
endif

題

我怎樣才能讓評論顏色變成這個主題的預期顏色？ 像這樣的東西： 我的 .vimrc 中是否有其他東西把它搞砸了？

Answer 1

跑：

:hi Comment

它應該返回應用於評論的顏色，例如：

:hi Comment
Comment        xxx term=bold ctermfg=242

在你的情況下，你還應該有：

ctermbg=value "where value != 0

所以運行：

:hi Comment ctermbg=0

這應該關閉評論的背景顏色。

要將其添加到 .vimrc：

hi Comment ctermbg=0

Answer 2

當我應用colorsheme后打開我的js文件時會出現這個問題。 評論和一些關鍵字（如import有難看的背景顏色，所以我不喜歡它。

我所做的是:hi然后按回車鍵，它將顯示所有突出顯示名稱及其顏色的列表。 選擇您要更改的名稱。 這是我的案例的示例。

:hi jsComment cterm=NONE
:hi jsImport cterm=NONE
:hi jsFrom cterm=NONE

希望這有幫助。