Excel計算多個工作表和列的平均值和中位數

Question

尋找一些Excel幫助。 我有以下工作表：

WORKSHEET WEEK1
A-------|B------|C------|D------
NAME    |GAME A |GAME B |GAME C
JIM      10      15      12
BILL     12      10      5
TED      
PHIL     0       8       17

WORKSHEET WEEK2
A-------|B------|C------|D------
NAME    |GAME D |GAME F |GAME B
JIM      15      10      9
BILL     
TED      3       21      18 
PHIL     12      2       30

基本上，我將有10個工作表（每周一個）。 我們正在跟蹤人們在一周內的彈球得分。 一周又一周（20台機器，每周只有6台機器），游戲/分數在表格上的順序不一樣。

我需要計算多個工作表中機器的平均值和中位數，並消除任何丟失或歸零的分數（因此10,0,10的平均值為10，中位數相同，數據丟失/ null相同）。

我在第一周使用了這個

=MEDIAN(IF('1B'!L:L>0,'1B'!L:L))

而且似乎只是令人討厭，但我正在努力將其作為不同列中的交叉表，不包括空白。

我並不反對使用另一張能夠查看所有工作表和列的工作表來找到游戲標題上的匹配項，然后抓住該列，計算，完成。 但如果我必須這樣做手冊，這完全不是問題。

我是一名C＃開發人員，所以我得到了代碼，我在Excel上的表現非常糟糕，語法讓我感到非常難過。

更新：預期輸出如下：游戲A：平均值：X，中位數Y游戲B：平均值：Z，中位數N

非常感謝！

Answer 1

假如說：

1）您有Excel 2007或更高版本

2）要查詢的每個工作表中的數據占用范圍A1:D5 （第1行中的標題和A列中的名稱）

3）您將您想要獲得所需結果的游戲選擇（例如“游戲B”）放在除被查詢之外的工作表的單元格A1中

首先轉到Name Manager （ Formulas選項卡）並進行以下定義：

名稱： SheetList

指： ={"Sheet1","Sheet2","Sheet3"}

（或者恰好相關的相關表格名稱。）

那么平均所需的array formula**是：

=AVERAGE(IFERROR(1/(1/N(INDIRECT(SheetList&TEXT(ROW(B2:D5)*10^5+TRANSPOSE(MODE.MULT(IF(T(INDIRECT(TRANSPOSE(SheetList)&TEXT(10^5+COLUMN(B2:D5),"!R0C00000"),0))=A1,COLUMN(B2:D5)),COLUMN(B2:D5))),"!R0C00000"),0))),""))

在上面用MEDIAN替換AVERAGE以獲得該游戲的等效中位數。

問候

**數組公式的輸入方式與“標准”公式的輸入方式不同。 您只需按住CTRL和SHIFT鍵，然后按ENTER鍵，而不是按ENTER鍵。 如果你已經正確地完成了它，你會注意到Excel在公式周圍放置了大括號{}（盡管不要嘗試自己手動插入這些）。