如何使用XSLT從元素中刪除一些內容

Question

對於圖像標簽，我需要使用JSON輸出中的XSLT僅保留具有“文件/”內容的圖像文件：

我的輸入XML文件是：

<image>binary/alias/my.jpg</image>

XSL用作：

<xsl:template match="image">
  image: <xsl:apply-templates/>,
</xsl:template>

我得到的JSON輸出是：

image: binary/alias/my.jpg

我需要的輸出為：

image: files/my.jpg

請幫我。 提前致謝。

Answer 1

在XSLT 2.0中，您可以執行以下操作：

<xsl:template match="image">
    <xsl:text>image: files/</xsl:text>
    <xsl:value-of select="tokenize(., '/')[last()]"/>
</xsl:template>

Answer 2

要在最后一次出現字符（在本例中為“ /”）之后獲取字符串，您需要（在XSLT-1.0中）一個遞歸模板。 應用此模板，解決方案很簡單：輸出所需的前綴文本'image：files /'並附加遞歸模板的結果：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:template match="image">
    image: files/<xsl:call-template name="LastOccurrence">
      <xsl:with-param name="value" select="text()" />
      <xsl:with-param name="separator" select="'/'" />
    </xsl:call-template>
  </xsl:template> 

  <xsl:template name="LastOccurrence">
    <xsl:param name="value" />
    <xsl:param name="separator" select="'/'" />

    <xsl:choose>
      <xsl:when test="contains($value, $separator)">
        <xsl:call-template name="LastOccurrence">
          <xsl:with-param name="value" select="substring-after($value, $separator)" />
          <xsl:with-param name="separator" select="$separator" />
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$value" />
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>

LastOccurrence模板是受此SO帖子啟發的。