VBA從第18行開始的列表數組？

Question

我有以下代碼，該代碼列出了數組中的唯一值：

Sub LIST()
  Dim arr As New Collection, a
  Dim aFirstArray() As Variant
  Dim i As Long

  aFirstArray() = Array("Banana", "Apple", "Orange", "Tomato", "Apple", _
  "Lemon", "Lime", "Lime", "Apple")

  On Error Resume Next
  For Each a In aFirstArray
     arr.Add a, a
  Next


  For i = 18 To arr.Count
     Cells(i, 3) = arr(i)
  Next

End Sub

我想從第18行開始列出這些值，但是當我設置I = 18時，這行不通。 請有人能告訴我我要去哪里錯嗎？

Answer 1

您可以切換到Dictionary對象並利用其Keys屬性：

Sub LIST()
    Dim aFirstArray() As Variant, a As Variant

    aFirstArray() = Array("Banana", "Apple", "Orange", "Tomato", "Apple", "Lemon", "Lime", "Lime", "Apple")

    With CreateObject("Scripting.Dictionary")
        For Each a In aFirstArray
            .Item(a) = a
        Next
        Cells(18, 3).Resize(.Count) = Application.Transpose(.Keys)
    End With

End Sub

Answer 2

或在以下情況下刪除重復項：

arr = Array("Banana", "Apple", "Orange", "Tomato", "Apple", "Lemon", "Lime", "Lime")
Set r = [C18].Resize(UBound(arr) + 1)
r = Application.Transpose(arr)
r.RemoveDuplicates 1