遍歷每個工作簿VBA中的工作簿和工作表

Question

我想循環瀏覽文件夾中的所有工作簿，然后循環瀏覽每個工作簿的所有工作表。 我有下面的代碼，但目前的問題是For Each ws in StrFile.Sheets ：

Sub LoopThroughFiles()
    Dim StrFile As String
    StrFile = Dir("C:\Users\A9900899\Desktop\bob\VBAProject\Raw\")
    Do While Len(StrFile) > 0
        Debug.Print StrFile
        For Each ws In StrFile.Sheets
            Debug.Print ws.Name
        Next ws
        StrFile = Dir
    Loop
End Sub

我這是什么錯

Answer 1

為了遍歷所有Workbook.Sheets ，需要Set wb為當前StrFile ，然后遍歷wb.Sheets 。

使用Application.ScreenUpdating = False和Application.DisplayAlerts = False將最大程度地減少所有屏幕閃爍和Excel警報。

碼

Option Explicit

Sub LoopThroughFiles()

    Dim StrFile As Variant
    Dim fPath As String
    Dim wb As Workbook
    Dim ws As Worksheet

    fPath = "C:\Users\A9900899\Desktop\bob\VBAProject\Raw\"
    StrFile = Dir(fPath)

    Application.ScreenUpdating = False
    Application.DisplayAlerts = False

    While StrFile <> ""
        Debug.Print StrFile
        If StrFile Like "*xls*" Then ' check that current file is Excel type
            Set wb = Workbooks.Open(fPath & StrFile)
            For Each ws In wb.Sheets
                Debug.Print ws.Name
            Next ws
            wb.Close False ' close workbook and don't save changes
        End If
        StrFile = Dir
    Wend
    Application.ScreenUpdating = True
    Application.DisplayAlerts = True

End Sub