使人偶模塊pcfens / filebeat正常工作

Question

我是這個網站和木偶的新手。 我正在嘗試為文件拍設置一個a模塊。 我希望Linux節點使用此模塊將日志發送到Logstash

我想要一個看起來像這樣的配置：

class { 'filebeat':
  outputs => {
    'logstash'     => {
     'hosts' => [
       '<FQDN>:5044',
     ],
     'enabled' => true,
    },
  },
}


filebeat::prospector { 'syslogs':
  paths    => [
    '/var/log/*.log',
    '/var/log/messages',
  ],
  doc_type => 'syslog-beat',
}

有沒有人對這個模塊或Puppet有任何經驗，可以告訴我如何使用上面的配置來配置這個模塊。 我現在一無所知，而且似乎找不到有關此模塊的大量文檔。 我真的很感謝朝正確方向介紹如何設置此模塊。

Answer 1

您可能想問一下如何啟動Control Repo 。 但是在執行此操作之前，請確保已閱讀“ 角色和配置文件”設計模式。

為使您入門，您將需要開始以下工作：

$ tree 
.
└── modules
    ├── profile
    │   └── manifests
    │       ├── base
    │       │   └── filebeat.pp
    │       └── base.pp
    └── role
        └── manifests
            ├── base
            └── myrole.pp

7 directories, 3 files

（顯然，從上面鏈接的示例中可以看到，最終它會包含更多內容。）

然后是您的基類：

$ cat modules/profile/manifests/base.pp 
class profile::base {
  include profile::base::filebeat
}

其中包括（您上面編寫的代碼）：

$ cat modules/profile/manifests/base/filebeat.pp 
class profile::base::filebeat {
  class { 'filebeat':
    outputs => {
      'logstash'     => {
       'hosts' => [
         '<FQDN>:5044',
       ],
       'enabled' => true,
      },
    },
  }

  filebeat::prospector { 'syslogs':
    paths => [
      '/var/log/*.log',
      '/var/log/messages',
    ],
    doc_type => 'syslog-beat',
  }
}

你的角色：

$ cat modules/role/manifests/myrole.pp 
class role::myrole {
  include profile::base
}

現在，只需確保將模塊目錄以一種或另一種方式復制到Puppet的modulepath中 ，就可以在本地主機上測試代碼。

如果是這樣，請嘗試：

# puppet module install pcfens/filebeat
# puppet apply -e 'include role::myrole'

只要正確安裝了Puppet，並且上面的代碼正確無誤，您就會上手。