獲取Haxe宏中的對象類型

Question

我想在宏中獲取一個對象的類，以便我可以訪問它的靜態變量：

// autoBuild macro adds static field "id_ : Int" to all subclasses
class Base {

}

class Child1 extends Base {
  public function new() {}
}

class Child2 extends Base {
  public function new() {}
}

class Container {
  public function addChild(index: Int, object: Base) {}

  macro function add(object: ???) {
    // find out class of on object
    // ???
    // var id = class.id_;
    this.addChild(id, object);
  }
}

所需用法：

var c = new Container();
c.add(new Child1());
c.add(new Child2());

Answer 1

您可以使用Context.typeof()來獲取表達式的類型 - 然后您需要進行一些模式匹配以找出類型的名稱。 以下僅適用於類，因為它只匹配TInst ，但可以擴展：

import haxe.macro.Context;
import haxe.macro.Expr;

class Container {
    // [...]

    public macro function add(self:Expr, object:Expr):Expr {
        var name = switch (Context.typeof(object)) {
            case TInst(_.get() => t, _): t.name;
            case _: throw "object type not found";
        }
        return macro $self.addChild($i{name}.id_, $object);
    }
}

這將生成以下代碼：

var c = new Container();
c.addChild(Child1.id_, new Child1());
c.addChild(Child2.id_, new Child2());

請注意，通過它的非限定名稱訪問_id只有在實際導入（或頂級）時才是安全的 - 實際上，您希望將t.pack與$p{}結合使用以生成完全限定的路徑。