使用XML :: LibXML進行XML解析

Question

這是試圖解析以提取與節點Company相對應的屬性值的樣本數據：公司節點下所有公司節點的CID，名稱，符號，值

<?xml version="1.0" encoding="UTF-8"?>
<StockRecords xmlns="http://url1"
              xmlns:ref="http://url2"
              xmlns:xsi="http://url3">
  <Companies>
    <Company>
      <CID>123</CID>
      <Name>Google</Name>
      <Symbol>GOOG</Symbol> 
      <Value>1234</Value>
    </Company>
  </Companies>
</StockRecords>

以下是我嘗試的2個變體。 變體1

use XML::LibXML;

my $filename = "test.xml";
my $dom = XML::LibXML->load_xml(location => $filename);

foreach my $sample ($dom->findnodes( '/Companies/Company' )) {

    print Dumper($sample);
    last;
}

方案2：由於其中涉及名稱空間，因此需要指定XPathContext。

use XML::LibXML;

my $filename = "test.xml";
my $parser = XML::LibXML->new();
my $xmldoc = $parser->parse_file($filename);

my $root = $xmldoc->getDocumentElement;

my @l = $root->getElementsByTagName('StockRecords');

my $xc = XML::LibXML::XPathContext->new($root);

$xc->registerNs("ns1", "http://url1");
$xc->registerNs("ref", "http://url2");
$xc->registerNs("xsi", "http://url3");

無法為節點的任何屬性提取數據。 我確實看過其他答案，但LibXML文檔仍然缺少某些內容。 請給我一些指導。 謝謝

Answer 1

use strict;
use warnings;
use feature qw( say );

use XML::LibXML               qw( );
use XML::LibXML::XPathContext qw( );

my $doc = XML::LibXML->load_xml( location => $ARGV[0] );

my $xpc = XML::LibXML::XPathContext->new();
$xpc->registerNs( ns1 => "http://url1" );

for my $company_node ($xpc->findnodes("/ns1:StockRecords/ns1:Companies/ns1:Company", $doc)) {
   say $xpc->findvalue("ns1:CID", $company_node);
   say $xpc->findvalue("ns1:Name", $company_node);
}