PLS-00201：標識符必須在程序中聲明

Question

我有一個 PL/SQL 過程代碼，它在/時運行，但在執行時不運行。 我得到的錯誤信息是

SQL> EXECUTE MAXINUM;
BEGIN MAXINUM; END;

      *
ERROR at line 1:
ORA-06550: line 1, column 7:
PLS-00201: identifier 'MAXINUM' must be declared
ORA-06550: line 1, column 7:
PL/SQL: Statement ignored

我正在處理的代碼是：

DECLARE
    N NUMBER;
    M NUMBER;
    O NUMBER;
    P NUMBER;
    X NUMBER;
PROCEDURE MAXINUM(N IN NUMBER, M IN NUMBER, O IN NUMBER, P IN NUMBER, X OUT NUMBER) IS
    BEGIN
    IF N>M AND N>O AND N>P THEN
        X:=N;
    ELSIF M>N AND M>O AND M>P THEN
        X:=M;
    ELSIF O>N AND O>M AND O>P THEN
        X:=O;
    ELSIF P>N AND P>M AND P>O  THEN
        X:=P;
    END IF;
    END;

BEGIN
    N:=&NUMBER;    
    M:=&NUMBER;
    O:=&NUMBER;
    P:=&NUMBER;
    MAXINUM(N,M,O,P,X);
    DBMS_OUTPUT.PUT_LINE('HIGHEST NUMBER = '||X);
END;
/

當它給出“標識符錯誤”時，我嘗試刪除此過程，但出現錯誤：

SQL> DROP PROCEDURE MAXINUM;
DROP PROCEDURE MAXINUM
*
ERROR at line 1:
ORA-04043: object MAXINUM does not exist

到目前為止，我已經閱讀了這個、 這個、 這個解決方案和其他一些與這個錯誤相關的解決方案。

Answer 1

您已經使用本地過程MAXINUM()編寫了一個匿名塊。 該過程可以在該塊內調用，但在該塊外不存在。 因此你不能獨立調用它。

如果要在其他地方使用該過程，則需要將其創建為一級數據庫對象：

create or replace procedure MAXINUM
   (N IN NUMBER, M IN NUMBER, O IN NUMBER, P IN NUMBER, X OUT NUMBER)
is 
BEGIN
    IF N>M AND N>O AND N>P THEN
        X:=N;
    ELSIF M>N AND M>O AND M>P THEN
        X:=M;
    ELSIF O>N AND O>M AND O>P THEN
        X:=O;
    ELSIF P>N AND P>M AND P>O  THEN
        X:=P;
    END IF;
END;
/

現在您可以在代碼中調用它，如下所示：

DECLARE
    N NUMBER;
    M NUMBER;
    O NUMBER;
    P NUMBER;
    X NUMBER;
BEGIN
    N:=&NUMBER;    
    M:=&NUMBER;
    O:=&NUMBER;
    P:=&NUMBER;
    MAXINUM(N,M,O,P,X);
    DBMS_OUTPUT.PUT_LINE('HIGHEST NUMBER = '||X);
END;
/

注意事項：

1. 如果參數為空會發生什么？
2. 如果兩個參數具有相同的值會發生什么？
3. 約定是將其聲明為函數並返回最高值，而不是設置 OUT 參數。

---

順便說一下，我假設您將這個作為練習，因為它是對現有 Oracle 內置函數greatest()的重新實現。