Qt Quick Controls 2 TextArea`tabChangesFocus`，如何使用Tab鍵更改焦點，而不是鍵入Tab字符

Question

來自Qt Quick Controls 1.x（ http://doc.qt.io/qt-5/qml-qtquick-controls-textarea.html ）的QML TextArea具有一個名為tabChangesFocus的屬性，可以將其設置為切換控件的行為。兩個可能的操作之間的Tab鍵：

• true ：在TextArea輸入Tab字符
• false ：將焦點移到選項卡鏈中的下一項

在Quick Controls 2.x（ https://doc.qt.io/qt-5/qml-qtquick-controls2-textarea.html ）中， TextArea似乎不存在此屬性。

默認值為true行為，但我想要false行為（焦點更改）。

有誰知道快速控制2實現相同效果的簡單方法？

Answer 1

將來應該可以更方便地使用它，但是您可以使用QML KeyNavigation設置選項卡導航：

import QtQuick 2.9
import QtQuick.Controls 2.2

ApplicationWindow {
    id: window
    width: 300
    height: 300
    visible: true

    Column {
        spacing: 20

        TextArea {
            id: textArea1
            focus: true
            text: "TextArea1"

            KeyNavigation.tab: textArea2
            KeyNavigation.backtab: textArea2
            KeyNavigation.priority: KeyNavigation.BeforeItem
        }

        TextArea {
            id: textArea2
            text: "TextArea2"

            KeyNavigation.tab: textArea1
            KeyNavigation.backtab: textArea1
            KeyNavigation.priority: KeyNavigation.BeforeItem
        }
    }
}

Answer 2

另一種方法是使用Item::nextItemInFocusChain() 。 這樣，您就不必知道焦點鏈中的下一項：

import QtQuick 2.9
import QtQuick.Controls 2.2

ApplicationWindow {
    id: window
    width: 300
    height: 300
    visible: true

    Column {
        spacing: 20

        TextArea {
            id: textArea1
            focus: true
            text: "TextArea1"

            Keys.onTabPressed: nextItemInFocusChain().forceActiveFocus(Qt.TabFocusReason)
        }

        TextArea {
            id: textArea2
            text: "TextArea2"
            objectName: text

            Keys.onTabPressed: nextItemInFocusChain().forceActiveFocus(Qt.TabFocusReason)
        }
    }
}