列的VBA遞歸循環

Question

誰能解釋我是否可以遞歸遍歷For循環內的排序列表？

我遍歷一列，一旦找到完全匹配（讓我們說EALOLES字符串），那么我想繼續循環直到沒有更多匹配為止。 資料范例

For i = 2 to UsedRange.Rows.Count
  If (Cells(i, 12).Value = "EALOLES") Then
    ' Start an inner loop until EALOLES ends, increment i++
    ' Perform actions appropriate to EALOLES case
    Exit For
  End If
next i

有了內部循環，這一切都很好，但是我只是想知道是否也可以通過遞歸函數來實現，那會是什么樣子？ 從我學到的有關遞歸的示例中，我可以想象從工作簿的末尾開始循環。

請注意，我並不是說這將是一個更好的解決方案，無論是內部循環，還是我很好奇。

Answer 1

您的問題基本上是這是遞歸的候選人，答案是否定的。 在這種情況下，使用內部循環進行迭代是更好的解決方案。

閱讀文章： 遞歸和迭代以了解何時使用它們。

Answer 2

假設您的數據已排序，則可以利用它

Dim nOccurrences As Long
Dim cell As Range
With Intersect(ActiveSheet.UsedRange, Columns(12))
    nOccurrences = WorksheetFunction.CountIf(.Cells, "EALOLES")
    If nOccurrences > 0 Then
        For Each cell in .Resize(nOccurrences).Offset(.Find(What:= "EALOLES", LookIn:=xlValues, LookAt:=xlWhole, After:=.Cells(.Rows.Count)).Row-1)
              ‘Do your things
        Next
    End If
End With

Answer 3

這不是返回排序列表中字符串的開始和結束位置的有效方法，但是作為一種知識型練習，應該這樣做。

dim i as long, j as long

For i = 2 to UsedRange.Rows.Count
  If (Cells(i, 12).Value = "EALOLES") Then
    for j=i to UsedRange.Rows.Count
      If (Cells(j+1, 12).Value <> "EALOLES") Then
        exit for
      end if
    next j
    Exit For
  End If
next i

debug.print "start: " & i
debug.print "end: " & j

Answer 4

我對同一主題的想法略有不同

定義要循環的范圍。 查看該值是否在范圍內。 如果是這樣，則從第一個匹配項開始，並繼續循環范圍，直到單元格值不同於指定的目標字符串。

Option Explicit

Sub StopAtEnd()

    Dim wb As Workbook
    Dim ws As Worksheet
    Dim endRow As Long

    Set wb = ThisWorkbook
    Set ws = wb.Worksheets("Sheet5")             'change as needed

    endRow = ws.Cells(ws.Rows.Count, "L").End(xlUp).Row

    Dim loopRange As Range

    Set loopRange = ws.Range("L1:L" & endRow) 'Change start row as required

    Dim currentCell As Range
    Dim targetString As String
    Dim startRow As Long

    targetString = "EALOLES"

    On Error GoTo Errhand

    startRow = Application.Match(targetString, loopRange, 0)

    Do Until ws.Range("L" & startRow) <> targetString
        Debug.Print ws.Range("L" & startRow).Address
        startRow = startRow + 1
    Loop

    Exit Sub

Errhand:

    MsgBox "Target string not found"

End Sub

向@DisplayName大喊大叫，后者指出可以這樣寫：

Option Explicit

Sub StopAtEnd()

    Dim wb As Workbook
    Dim ws As Worksheet
    Dim endRow As Long

    Set wb = ThisWorkbook
    Set ws = wb.Worksheets("Sheet1")             'change as needed

    endRow = ws.Cells(ws.Rows.Count, "L").End(xlUp).Row

    Dim loopRange As Range

    Set loopRange = ws.Range("L1:L" & endRow) 'Change start row as required

    Dim currentCell As Range
    Dim targetString As String
    Dim startRow As Variant

    targetString = "EALOLES"

    startRow = Application.Match(targetString, loopRange, 0)

    If IsError(startRow) Then

        MsgBox "Target string not found"

    Else

        Do Until ws.Range("L" & startRow) <> targetString

            Debug.Print ws.Range("L" & startRow).Address
            startRow = startRow + 1

        Loop

   End If

End Sub