Excel根據時間和名稱讀取數據

Question

我有一張工作表，其中維護了所有項目和資源的詳細信息。 我需要知道項目之間是否有空閑資源。 假設一個團隊中有x個人，我需要知道在項目之間有人可用的持續時間以及下一個項目何時開始。

示例：表1：項目和資源的詳細信息

 <table> <tr> <td>Name</td> <td>Project</td> <td>Start Date</td> <td>End Date</td> </tr> <tr> <td>A</td> <td>X</td> <td>01 Jan 2019</td> <td>31 Mar 2019</td> </tr> <tr> <td>B</td> <td>Y</td> <td>05 Jan 2019</td> <td>01 May 2019</td> </tr> <tr> <td>A</td> <td>Z</td> <td>15 Apr 2019</td> <td>01 Sep 2019</td> </tr> </table> 

在上述情況下，人A有兩個項目X和Z，在兩個項目之間有15天的時間。 我想要一張像下面的桌子。

表2：

 <table> <tr> <td>Name</td> <td>Current Project</td> <td>End Date</td> <td>Next Project</td> <td>Start Date</td> <td>Duration</td> </tr> <tr> <td>A</td> <td>X</td> <td>31 Mar 2019</td> <td>Z</td> <td>15 Apr 2019</td> <td>15</td> </tr> <tr> <td>B</td> <td>Y</td> <td>01 May 2019</td> <td></td> <td></td> <td></td> </tr> </table> 

如果未分配下一個項目，則下一個項目，開始日期和持續時間可以為空。 我不想為此編寫VBA，我只想使用函數來實現這一點。 可能嗎？

Answer 1

我已將您的數據轉換為Excel表（使用Ctrl + T鍵盤快捷鍵），並使用以下公式：

E2： =IF(MAX(([Name]=[@Name])*([Start Date]>[@[End Date]])*[Start Date])>0,MAX(([Name]=[@Name])*([Start Date]>[@[End Date]])*[Start Date]),"")

F2： =IF(ISNUMBER([@[Next Project Start Date]]),[@[Next Project Start Date]]-[@[End Date]],"")

請注意，E2中的公式是一個數組輸入的公式：您必須使用Ctrl + Shift + E將其輸入到Excel中

Answer 2

我認為沒有必要獲得第三個項目。 首先，您應該獲得唯一的名稱（列A ）。 這可以等來完成這或通過使用unique()在谷歌工作表的情況下功能。 假設輸入范圍被Sheet1!A2:A9 ，上Sheet2就可以得到第一個名稱（ A通過在進入下面陣列式在這種情況下） A2 ：

{=IFERROR(INDEX(Sheet1!$A$2:$A$9, MATCH(0,COUNTIF($A$1:A1, Sheet1!$A$2:$A$9), 0)),"")}

現在在Sheet2添加一個輔助列G 在G2輸入以下公式以獲取名字（ A ）的當前匹配行索引：

=MATCH($A2, Sheet1!$A$2:$A$9, 0)

添加另一個幫助列H 您可以像這樣（在H2 ）獲得名字（ A ）的下一個匹配行索引：

=MATCH($A2, OFFSET(Sheet1!$A$2:$A$9, $G2, 0, 8), 0)+$G2

請注意， 8是Sheet1!$A$2:$A$9的硬編碼高度。 如果輸入范圍更改，則也應更改該值。

現在，您可以獲得這樣的當前項目名稱（在B2 ）：

=INDEX(Sheet1!$B$2:$B$9, $G2)

和下一個項目名稱（在D2 ）：

=INDEX(Sheet1!$B$2:$B$9, $H2)

當前項目結束日期（在C2 ）：

=INDEX(Sheet1!$D$2:$D$9, $G2)

下一個項目開始日期（在E2 ）：

=INDEX(Sheet1!$C$2:$C$9, $H2)

然后持續時間是微不足道的（在F2 ）：

=E2-C2

然后復制2:2並粘貼到3:9 。 做完了

示例文件在這里 。 我已經用ifError()在文件中包裝了每個單元格。