從csv在兩個節點之間創建具有不同屬性的相同類型的多個關系

Question

在Neo4jDesktop中的兩個節點之間創建具有不同屬性的相同類型的多個關系時，我遇到了問題。

Nodes dataset:
    File Name: 1.csv
    File Contents:
        Id,Desc
        A,Alpha
        B,Beta
        C,Charlie
        D,Doyce

Relationships Dataset:
    File Name: 2.csv
    File Contents:
        SeqNo,Date,Count,Weight,From,To
        0,2018-04-01,12,308,A,B
        1,2018-04-01,3,475,B,C
        2,2018-04-01,23,308,C,D
        3,2018-04-01,32,524,D,A
        4,2018-04-01,0,308,A,C
        5,2018-04-01,23,237,B,D
        6,2018-04-01,54,308,B,A
        7,2018-04-01,23,237,D,B
        8,2018-04-01,18,308,D,C
        9,2018-04-01,23,308,C,A
        10,2018-04-01,78,475,B,C
        11,2018-04-01,67,308,A,B
        12,2018-04-01,56,237,D,B
        13,2018-04-01,34,308,A,C
        14,2018-04-01,27,524,A,D
        15,2018-04-01,84,237,D,B


// Create Nodes
USING PERIODIC COMMIT
LOAD CSV WITH HEADERS FROM "file:/1.csv" AS row
CREATE (:Node {Id: row.Id, Desc: row.Desc});

// Create Relationships
USING PERIODIC COMMIT
LOAD CSV WITH HEADERS FROM "file:/2.csv" AS row
MERGE (from:Node {Id: row.From})
MERGE (to:Node {Id: row.To})
MERGE (from)-[rel:RELATED_AS]->(to)
ON CREATE SET rel.SeqNo  = toInt(row.SeqNo), 
              rel.Date   = row.flightDate, 
              rel.Count  = toInteger(row.Count), 
              rel.Weight = toFloat(row.Weight)

該語法有效並且僅創建11個關系，兩個節點之間具有傳入和傳出關系。

它忽略了AB，BC，AC和DB之間的其他關系（2個其他關系）。

如何創建具有所有16個關系的圖？

提前致謝。

梅爾。

Answer 1

您的第二個查詢是合並(from)-[rel:RELATED_AS]->(to)以便Cypher匹配該模式（如果存在）。 因此，后續的匹配，但是由於ON CREATE語句，因此永遠不會更新值。

由於您希望每次都創建關系，因此可以將語句替換為以下內容。

USING PERIODIC COMMIT
LOAD CSV WITH HEADERS FROM "file:/2.csv" AS row
MERGE (from:Node {Id: row.From})
MERGE (to:Node {Id: row.To})
CREATE (from)-[rel:RELATED_AS {SeqNo: row.SeqNo, Date: row.flightDate, Count: toInteger(row.Count), Weight: toFloat(row.Weight)}]->(to)