Excel VBA 用時間轉換日期

Question

我有 2 個帶有時間數據的單元格，其格式如下：

"A1" = Sep 01 2018 00:01:33.707 
"A2" = Sep 01 2018 00:01:49.917

我需要在excel VBA中創建一個按鈕和方法，如果時間“A2”比“A1”多90秒，則將“A3”單元格設置為true。 這是我到目前為止所擁有的，但它不起作用：

Sub Macro2()
    Dim str1 As String, str2 As String

    With Worksheets("sheet5")

        str1 = .Cells(1, "A").Text
        str2 = .Cells(2, "A").Text

        'greater than 90m seconds in A3
        .Cells(3, "A") = CBool(Abs((DateValue(Left(str1, 6) & "," & Mid(str1, 7, 5)) + _
                                    TimeValue(Mid(str1, 13, 8)) + TimeSerial(0, 0, 1) * CDbl(Right(str1, 4))) - _
                                   (DateValue(Left(str2, 6) & "," & Mid(str2, 7, 5)) + _
                                   TimeValue(Mid(str2, 13, 8)) + TimeSerial(0, 0, 1) * CDbl(Right(str2, 4)))) > _
                                   TimeSerial(0, 0, 90))
        'actual absolute difference in A4
        .Cells(4, "A") = Abs((DateValue(Left(str1, 6) & "," & Mid(str1, 7, 5)) + _
                                    TimeValue(Mid(str1, 13, 8)) + TimeSerial(0, 0, 1) * CDbl(Right(str1, 4))) - _
                                   (DateValue(Left(str2, 6) & "," & Mid(str2, 7, 5)) + _
                                    TimeValue(Mid(str2, 13, 8)) + TimeSerial(0, 0, 1) * CDbl(Right(str2, 4))))
    End With End Sub

上面給出了錯誤，因為日期函數適用於系統語言環境，在我的情況下是希伯來語，而數據是英語。

另一種可能有幫助的方法是將所有列“A”（保存日期）轉換為可與 VBA 上的日期和時間函數一起使用的系統本地日期（不知道如何執行）。

請幫忙

Answer 1

我已將您的任務分為 3 個功能。

a) 輔助函數將月份的 3 個字符轉換為整數。 它看起來有點笨拙，可能還有其他方法，但使用大型Select Case的優點是，如果出現不同語言的月份名稱，則易於理解和適應：

Function getMonthFromName(monthName As String) As Integer

    Select Case UCase(monthName)
        Case "JAN": getMonthFromName = 1
        Case "FEB": getMonthFromName = 2
        Case "MAR": getMonthFromName = 3
        Case "APR": getMonthFromName = 4
        (...)
        Case "SEP": getMonthFromName = 9
        (...)
    End Select

End Function

b) 將字符串轉換為日期的函數。 它采用您提供的形式的日期格式，但如果格式發生變化，它很容易適應（為簡單起見，秒四舍五入）

Function GetDateFromString(dt As String) As Date

    Dim tokens() As String
    tokens = Split(Replace(dt, ":", " "), " ")

    Dim day As Integer, month As Integer, year As Integer
    month = getMonthFromName(CStr(tokens(0)))
    day = Val(tokens(1))
    year = Val(tokens(2))

    Dim hour As Integer, minute As Integer, second As Double
    hour = Val(tokens(3))
    minute = Val(tokens(4))
    second = Round(Val(tokens(5)), 0)

    GetDateFromString = DateSerial(year, month, day) + TimeSerial(hour, minute, second)
End Function

c) 以秒為單位計算兩個日期差的函數。 VBA（和許多其他環境）中的日期存儲為Double ，其中 Date-Part 是整數部分，日期是余數。 這使得使用日期值計算變得容易。

Function DateDiffInSeconds(d1 As String, d2 As String) As Long
    Dim diff As Double
    diff = GetDateFromString(d2) - GetDateFromString(d1)
    DateDiffInSeconds = diff * 24 * 60 * 60
End Function

更新以處理毫秒：更改GetDateFromString函數。 在這種情況下， DateDiffInSeconds應該返回double而不是long 。

Function GetDateFromString(dt As String) As Date

    Const MillSecPerHour As Long = 24& * 60 * 60 * 1000

    Dim tokens() As String
    tokens = Split(Replace(Replace(dt, ".", " "), ":", " "), " ")

    Dim day As Integer, month As Integer, year As Integer
    month = getMonthFromName(CStr(tokens(0)))
    day = Val(tokens(1))
    year = Val(tokens(2))

    Dim hour As Integer, minute As Integer, second As Integer, milli As Integer
    hour = Val(tokens(3))
    minute = Val(tokens(4))
    second = Val(tokens(5))
    milli = Val(tokens(6))

    GetDateFromString = DateSerial(year, month, day) _
                      + TimeSerial(hour, minute, second) _
                      + milli / MillSecPerHour
End Function

Answer 2

我認為你把它復雜化了，試試這個來了解如何做到這一點：

Sub Macro2()
    Dim str1 As String, str2 As String

    With Worksheets("sheet5")

        .Range("b1:e1") = Split(Range("A1"), " ")
        .Range("B2:e2") = Split(Range("A2"), " ")


End Sub

Answer 3

為了您的信息，我以稍微不同（且更簡單）的方式完成了您正在做的事情：

在單元格 B2 中，我輸入值13/11/2018 11:44:00 。
在單元格 B3 中，我輸入值13/11/2018 11:45:01 。
（對於這兩個單元格，單元格格式已設置為d/mm/jjjj u:mm:ss ）。

在另一個單元格中，我輸入了以下公式：

=IF((B3-B2)*86400>90;TRUE;FALSE)

該公式基於設置日期時間值的思想，基於一天等於1的思想，一天有86400秒。

像這樣，您可以在不需要 VBA 的情況下計算時差。

Answer 4

使用 UDF。

Sub Macro2()
    Dim str1 As String, str2 As String
    Dim mySecond As Double, t1 As Double, t2 As Double, t3 As Double
    mySecond = TimeSerial(0, 0, 90)

    With Worksheets("sheet5")
        str1 = .Cells(1, "A").Text
        str2 = .Cells(2, "A").Text
        t1 = ConvertTime(str1)
        t2 = ConvertTime(str2)
        t3 = t2 - t1
        .Cells(3, "a") = Abs(t3) >= mySecond
    End With

End Sub
Function ConvertTime(s As String)
    Dim vS
    vS = Split(s, " ")
    ConvertTime = DateValue(vS(0) & "-" & vS(1) & "-" & vS(2)) + TimeValue(Split(vS(3), ".")(0))
End Function