保存NSIS安裝日志

Question

保存NSIS中顯示的安裝日志的最簡單方法是什么？ 我似乎記得在某處你可以用特殊標志重新編譯NSIS代碼以使其能夠保存日志。 有更容易的方法嗎？

Answer 1

為了保持文件大小較小，NSIS編譯器的默認安裝不會生成日志文件。 下載一個版本的特殊版本並將其復制到makensis.exe應用程序（和Stub文件夾）上以對其進行修補以獲得日志記錄支持。

完成后，只需將以下內容添加到腳本中：

 LogSet on 

無需其他更改。 我不知道為什么這不是默認值，因為在我的情況下，它只增加48個字節到文件大小！

Answer 2

試試NSISLog插件。

還有LogEx 。

Answer 3

這是NSIS網站上直接提供的解決方案

StrCpy $0 "$EXEDIR\install.log"
Push $0
Call DumpLog



!define LVM_GETITEMCOUNT 0x1004
!define LVM_GETITEMTEXT 0x102D

Function DumpLog
  Exch $5
  Push $0
  Push $1
  Push $2
  Push $3
  Push $4
  Push $6

  FindWindow $0 "#32770" "" $HWNDPARENT
  GetDlgItem $0 $0 1016
  StrCmp $0 0 exit
  FileOpen $5 $5 "w"
  StrCmp $5 "" exit
    SendMessage $0 ${LVM_GETITEMCOUNT} 0 0 $6
    System::Alloc ${NSIS_MAX_STRLEN}
    Pop $3
    StrCpy $2 0
    System::Call "*(i, i, i, i, i, i, i, i, i) i \
      (0, 0, 0, 0, 0, r3, ${NSIS_MAX_STRLEN}) .r1"
    loop: StrCmp $2 $6 done
      System::Call "User32::SendMessageA(i, i, i, i) i \
        ($0, ${LVM_GETITEMTEXT}, $2, r1)"
      System::Call "*$3(&t${NSIS_MAX_STRLEN} .r4)"
      FileWrite $5 "$4$\r$\n"
      IntOp $2 $2 + 1
      Goto loop
    done:
      FileClose $5
      System::Free $1
      System::Free $3
  exit:
    Pop $6
    Pop $4
    Pop $3
    Pop $2
    Pop $1
    Pop $0
    Exch $5
FunctionEnd