VBA，避免溢出錯誤，修剪工作表功能

Question

我在嘗試修剪范圍內的單元格時遇到溢出錯誤。 我得到錯誤的那一行是， C.Value = .Trim(C.Value)也許這可以在不相交的情況下完成？ 我試過沒有它，但它會導致不匹配錯誤。

    Dim masterWB As Workbook
    Dim dailyWB As Workbook
    Dim C As Range

    Application.DisplayAlerts = False

    'Set Current Workbook as Master
    Set masterWB = Application.ThisWorkbook
    'Set some Workbook as the one you are copying from
    Set dailyWB = Workbooks.Open("excelguy.xlsm")


    'Copy the Range from dailyWB and Paste it into the MasterWB
    dailyWB.Sheets("Summary").Range("A1:BJ200").Copy masterWB.Sheets("Master Summary").Range("A1").Rows("1:1")
    'formatting and paste as values
    Workbooks("excelguy Master.xlsm").Activate
    Worksheets("Master Summary").Select

    'trim values
    columns("A:BJ").Select
       With Application.WorksheetFunction
        For Each C In Intersect(columns("A:BJ"), ActiveSheet.UsedRange)  
            C.Value = .Trim(C.Value)  'Overflow Error
        Next C
        End With

任何幫助，將不勝感激。

Answer 1

1. 無需.Select或.Activate您的工作簿/工作表。 您聲明了工作簿變量，因此請使用它們！
2. UsedRange可能不可靠。 我建議切換到更標准的最后一行計算。 現在，代碼正在使用Column A來確定您范圍內所有列的最后一行，作為回報，這決定了您將要循環的范圍。
3. 正如@dwirony 所述，可以直接從VBA調用TRIM函數。

請參閱下面@Tim Williams 的評論，以確定 Trim 的 VBA 版本是否可以接受

---

Option Explicit

Sub Test()

Dim masterWB As Workbook, dailyWB As Workbook
Dim C As Range, LRow As Long

Set masterWB = Application.ThisWorkbook
Set dailyWB = Workbooks.Open("excelguy.xlsm")

dailyWB.Sheets("Summary").Range("A1:BJ200").Copy masterWB.Sheets("Master Summary").Range("A1").Rows("1:1")

With masterWB.Sheets("Master Summary")
  LRow = .Range("A" & .Rows.Count).End(xlUp).Row
    For Each C In .Range("A2:BJ" & LRow)
        C.Value = Trim(C)
        'C.Value = Application.WorksheetFunction.Trim(C)
    Next C
End With

End Sub

如果您只是修剪值，則可以將范圍加載到數組中，將值修改為新數組，然后將新修剪過的數組的值轉移到范圍

Answer 2

嘗試這個。 使用 Variant Array 更快。

Sub Test()

    Dim masterWB As Workbook, dailyWB As Workbook
    Dim C As Range, LRow As Long
    Dim Ws As Worksheet
    Dim rngDB As Range, vDB As Variant
    Dim i As Long, j As Long

    Set masterWB = ThisWorkbook
    Set dailyWB = Workbooks.Open("excelguy.xlsm")
    Set Ws = masterWB.Sheets("Master Summary")

    dailyWB.Sheets("Summary").Range("A1:BJ200").Copy Ws.Range("A1")
    Ws.Activate
    With Ws
        Set rngDB = .UsedRange
        vDB = rngDB
        For i = 1 To UBound(vDB, 1)
            For j = 1 To UBound(vDB, 2)
                vDB(i, j) = Trim(vDB(i, j))
            Next j
        Next i
        rngDB = vDB
    End With

End Sub