相當於scala中的assoc-in（clojure）

Question

我正在嘗試在scala中找到assoc-in（clojure）的等效項。 我正在嘗試轉換

(defn- organiseDataByTradeId [data]
(reduce #(let [a (assoc-in %1 
                        [(%2 "internaltradeid") (read-string (%2 "paramseqnum")) "levelcols"] 
                        (reduce (fn [m k](assoc m k (get %2 k))) 
                                {} 
                                (string/split xmlLevelAttributesStr #",")))
            b (assoc-in a



                      [(%2 "internaltradeid") (read-string (%2 "paramseqnum")) "subLevelCols" (read-string (%2 "cashflowseqnum"))]
                         (reduce (fn [m k] (assoc m k (get %2 k))) 
                                {} 
                                (string/split xmlSubLevelAttributesStr #","))               
                        )] 
            b)
      {}
      data))

斯卡拉。 嘗試過這個：

def organiseDataByTradeId(data: List[Map[String, String]]) = {
    data.map { entry => Map(entry("internaltradeid") -> Map(entry("paramseqnum").toInt -> Map("levelcols" -> (xmlLevelAttributesStr.split(",")).map{key=> (key,entry(key))}.toMap,
        "subLevelCols" -> Map(entry("cashflowseqnum").asInstanceOf[String].toInt -> (xmlSubLevelAttributesStr.split(",")).map{key=> (key,entry(key))}.toMap)))) }

  }

不知道如何合並我得到的地圖列表而不會覆蓋。 這里的數據 List [Map [String，String]]基本上是描述一個表。每個條目是一行。列名是映射的鍵，值是值。 xmlLevelAttributeStr和xmlSubLevelAttributeStr是兩個字符串，其中列名用逗號分隔。 我對scala還是陌生的。 我將每一行（Map [String，String]）轉換為一個Scala Map，現在不知道如何合並它們，這樣以前的數據就不會被覆蓋並且行為與clojure代碼完全相同。此外，我也不允許使用外部庫，例如scalaz。

Answer 1

這段Clojure代碼不是一個很好的復制模式：它有很多重復項，並且很少解釋它在做什么。 我會這樣寫：

(defn- organiseDataByTradeId [data]
  (let [level-reader (fn [attr-list]
                       (let [levels (string/split attr-list #",")]
                         (fn [item]
                           (into {} (for [level levels]
                                      [level (get item level)])))))
        attr-levels (level-reader xmlLevelAttributesStr)
        sub-levels (level-reader xmlSubLevelAttributesStr)]
    (reduce (fn [acc item]
              (update-in acc [(item "internaltradeid"),
                              (read-string (item "paramseqnum"))]
                         (fn [trade]
                           (-> trade
                               (assoc "levelcols" (attr-levels item))
                               (assoc-in ["subLevelCols", (read-string (item "cashflowseqnum"))]
                                         (sub-levels item))))))
            {}, data)))

它比原始代碼多了幾行代碼，但是我借此機會命名了許多有用的概念，並將重復內容提取到局部函數中，以使其更加不言自明。

如果您知道將不會重復internaltradeid，這甚至會更加容易：您可以簡單地生成許多獨立的映射並將它們合並在一起：

(defn- organiseDataByTradeId [data]
  (let [level-reader (fn [attr-list]
                       (let [levels (string/split attr-list #",")]
                         (fn [item]
                           (into {} (for [level levels]
                                      [level (get item level)])))))
        attr-levels (level-reader xmlLevelAttributesStr)
        sub-levels (level-reader xmlSubLevelAttributesStr)]
    (apply merge (for [item data]
                   {(item "internaltradeid")
                    {(read-string (item "paramseqnum"))
                     {"levelcols" (attr-levels item),
                      "subLevelCols" {(read-string (item "cashflowseqnum")) (sub-levels item)}}}}))))

但是，實際上，這兩種方法都無法在Scala中很好地工作，因為Scala與Clojure具有不同的數據建模原理。 Clojure鼓勵像這樣寬松定義的異構地圖，Scala希望您的地圖是同質的。 當您需要將多種類型的數據混合在一起時，Scala建議您定義一個類（或者也許是一個案例類-我不是Scala專家），然后創建該類的實例。

因此，在這里，您需要一個Map[String, Map[Int, TradeInfo]] ，其中TradeInfo是一個具有兩個字段的類，即levelcols : List[Attribute]和subLevelCols作為某種配對（或者可能是一個單元素的地圖） ），其中包含cashflowseqnum和另一個List[Attribute] 。

以Scala方式對數據建模后，您將無法使用任何看起來像assoc-in東西，因為您的數據將不會是一個巨大的地圖，因此不會出現問題。