F＃重寫計算表達式

Question

我正在研究延續，因為我想對協同程序進行一些有趣的使用......無論如何，我想更好地理解我發現的一個實現。

為此我想重寫實現而不使用計算表達式（continuation Monad），但我不能完成它。

我有這個：

type K<'T,'r> = (('T -> 'r) -> 'r)

let returnK x = (fun k -> k x)
let bindK m f = (fun k -> m (fun a -> f a k))
let runK (c:K<_,_>) cont = c cont
let callcK (f: ('T -> K<'b,'r>) -> K<'T,'r>) : K<'T,'r> =
    fun cont -> runK (f (fun a -> (fun _ -> cont a))) cont

type ContinuationBuilder() =
    member __.Return(x) = returnK x
    member __.ReturnFrom(x) =  x
    member __.Bind(m,f) =  bindK m f
    member this.Zero () = this.Return ()

let K = new ContinuationBuilder()

/// The coroutine type from http://fssnip.net/7M
type Coroutine() =
    let tasks = new System.Collections.Generic.Queue<K<unit,unit>>()

    member this.Put(task) =

        let withYield = K {
            do! callcK (fun exit ->
                    task (fun () ->
                        callcK (fun c ->
                            tasks.Enqueue(c())
                            exit ())))
            if tasks.Count <> 0 then
                do! tasks.Dequeue() }
        tasks.Enqueue(withYield)

    member this.Run() =
        runK (tasks.Dequeue()) ignore 

// from FSharpx tests
let ``When running a coroutine it should yield elements in turn``() =
  // This test comes from the sample on http://fssnip.net/7M
  let actual = System.Text.StringBuilder()
  let coroutine = Coroutine()
  coroutine.Put(fun yield' -> K {
    actual.Append("A") |> ignore
    do! yield' ()
    actual.Append("B") |> ignore
    do! yield' ()
    actual.Append("C") |> ignore
    do! yield' ()
  })
  coroutine.Put(fun yield' -> K {
    actual.Append("1") |> ignore
    do! yield' ()
    actual.Append("2") |> ignore
    do! yield' ()
  })
  coroutine.Run()
  actual.ToString() = "A1B2C"

``When running a coroutine it should yield elements in turn``()

所以，我想在不使用計算表達式K情況下重寫Coroutine類的Put成員。

我當然讀過這 本以及其他幾篇關於catamorphisms的文章，但是重寫這個延續monand並不是很容易，因為它是重寫Write Monad的例子......

我嘗試了幾種方法，這是其中之一：

member this.Put(task) =

    let withYield =
        bindK
            (callcK (fun exit ->
                task (fun () ->
                    callcK (fun c ->
                        tasks.Enqueue(c())
                        exit ()))))
            (fun () ->
                if tasks.Count <> 0 
                then tasks.Dequeue()
                else returnK ())
    tasks.Enqueue(withYield)

當然它不起作用:(

（順便說一句：有一些關於編譯器應用於在普通F＃中重寫計算的所有規則的大量文檔？）

Answer 1

您的Put版本幾乎是正確的。 但有兩個問題：

• bindK函數正在向后使用，需要交換參數。
• task應該傳遞給Cont<_,_> -> Cont<_,_> ，而不是unit -> Cont<_,_> -> Cont<_,_> 。

修復這些問題可能如下所示：

    member this.Put(task) =
        let withYield =
            bindK
                (fun () ->
                    if tasks.Count <> 0 
                    then tasks.Dequeue()
                    else returnK ())
                (callcK (fun exit ->
                    task (
                        callcK (fun c ->
                            tasks.Enqueue(c())
                            exit ()))))
        tasks.Enqueue(withYield)

當然它不是太優雅。 使用bind ，最好聲明一個operator >>= ：

let (>>=) c f = bindK f c

那樣

• do! 轉換為放置>>= fun () ->之后
• let! a = let! a =轉換為放置>>= fun a -> after

然后你的代碼看起來會更好一些：

    member this.Put2(task) =
        let withYield =
            callcK( fun exit ->
                    task( callcK (fun c ->  
                        tasks.Enqueue(c())
                        exit())
                    )
                ) >>= fun () -> 
            if tasks.Count <> 0 then
                tasks.Dequeue() 
            else returnK ()
        tasks.Enqueue withYield