根據單元格值刪除行不起作用

Question

我在名為 New 的工作表中有一些數據，我的數據在 A 列到 K 列中。但是，出於數據分析目的，E 到 H 列有意留空，而且我沒有標題，因此我的數據從單元格 A1 開始。 現在在 A 列中，我們在單元格中有顏色，我想刪除所有不是白色的行，因此保留沒有顏色的行。

我做了一些研究，但我在網上得到的所有代碼要么刪除整個工作表，要么只是通過代碼，但沒有任何反應。 下面是我目前正在使用的那些沒有任何作用的。 我用F8還是沒有錯誤。

查看我的示例數據的圖像，我正在嘗試使用沒有任何顏色的單元格獲得結果。 我試圖刪除顏色索引的引號，但仍然不起作用。

 Sub deleterow()

 lastRow = Worksheets("New").Cells(Rows.Count, "A").End(xlUp).Row
 For i = lastRow To 1 Step -1
      If Worksheets("New").Cells(i, 1).Interior.ColorIndex <> "2" Then
           Rows(i).EntireRow.Delete
           i = i + 1
      End If
 Next I

 End Sub

Answer 1

試試下面的代碼：

Option Explicit

Sub deleterow()

Dim i As Long, LastRow As Long

With Worksheets("New")
    LastRow = .Cells(.Rows.Count, "A").End(xlUp).Row

    For i = LastRow To 1 Step -1
        'If .Cells(i, 1).Interior.Color <> xlNone Then
        ' replace RGB(255, 255, 255) with the "white" color
        If .Cells(i, 1).Interior.Color <> RGB(255, 255, 255) Then
            .Rows(i).Delete
        End If
    Next i
End With

End Sub

Answer 2

刪除無顏色行

聯盟版

Option Explicit

Sub DeleteNoColorRow()

    Const cSheet As Variant = "Sheet1"  ' Worksheet Name/Index
    Const cFirstR As Integer = 1        ' First Row
    Const cColumn As Variant = "A"      ' Column Letter/Number

    Dim rngU As Range     ' Union Range
    Dim lastRow As Long   ' Last Row
    Dim i As Long         ' Row Counter

    With ThisWorkbook.Worksheets(cSheet)
        lastRow = .Cells(.Rows.Count, cColumn).End(xlUp).Row
        For i = cFirstR To lastRow
            If .Cells(i, cColumn).Interior.ColorIndex <> xlNone Then
                If Not rngU Is Nothing Then
                    Set rngU = Union(rngU, .Cells(i, cColumn))
                  Else
                    Set rngU = .Cells(i, cColumn)
                End If
            End If
        Next
    End With

    If Not rngU Is Nothing Then
        rngU.EntireRow.Delete ' Hidden = True
        Set rngU = Nothing
    End If

End Sub