當字符串具有可變的定界符時，VBA將字符串拆分為多個單元格

Question

如果我將以下信息全部包含在一個單元格中，並且想要將其拆分為單獨的單元格。 我知道如何使用空格作為定界符，但在這種情況下，名稱也包含空格，我希望名稱可以在單個單元格中保持在一起。 使問題進一步復雜化的是，名稱不總是總是只有第一名和姓氏，它還可以包括中間名，因此並不總是一個標准的兩個名稱。

2172571122  Jane Doe 3143332222 John Doe

2172242237 Mary Mixer 2223334444 Mike M Martin

希望它最終看起來像這樣：

Cell 1 = 2172242237 
Cell 2 = Mary Mixer 
Cell 3 = 2223334444 
Cell 4 = Mike M Martin

有什么建議么？

Answer 1

這個基於正則表達式的函數在數字和文本（單詞）之間交替分割。

Option Explicit

Function customSplit(str As String, _
                     Optional ndx As Integer = 1) As Variant

    Static rgx As Object, cmat As Object

    Set rgx = CreateObject("VBScript.RegExp")

    With rgx
        .Global = True
        .MultiLine = True
        .IgnoreCase = True
        If CBool(ndx Mod 2) Then
            .Pattern = "[0-9]{10}"
            ndx = (ndx + 1) \ 2
        Else
            .Pattern = "[A-Z]{1,9}\s[A-Z]{1,9}[\s[A-Z]{1,9}]?"
            ndx = ndx \ 2
        End If
        If .test(str) Then
            Set cmat = .Execute(str)
            If ndx <= cmat.Count Then
                customSplit = cmat.Item(ndx - 1)
            End If
        End If
    End With

End Function

Answer 2

您可以嘗試：

Option Explicit

Sub test()

    Dim strToSplit As String, strImport As String
    Dim arrwords As Variant
    Dim i As Long, counter As Long

    With ThisWorkbook.Worksheets("Sheet1")
        strToSplit = .Range("A1").Value
        arrwords = Split(strToSplit, " ")

        counter = 1

        For i = LBound(arrwords) To UBound(arrwords)

            If IsNumeric(arrwords(i)) = True Then
                strImport = arrwords(i)
                .Cells(3, counter).Value = strImport
                counter = counter + 1
            ElseIf Not IsNumeric(arrwords(i)) = True Then
                If Not IsNumeric(.Cells(3, counter - 1).Value) Then
                    strImport = .Cells(3, counter - 1) & " " & arrwords(i)
                    .Cells(3, counter - 1).Value = strImport
                    counter = counter
                Else
                    strImport = arrwords(i)
                    .Cells(3, counter).Value = strImport
                    counter = counter + 1
                End If
            End If

        Next

    End With

End Sub

結果如下：

Answer 3

關於您可以做什么，我有一些想法。

1）讀一行

在每個拆分值上執行isNumeric isNumeric()時，執行split(line, " ")並遍歷索引。 如果不是，則添加到字符串Array（）並將標志設置為true。

然后，如果是數字，則期望另一個名稱並將標志設置為true。

2）讀一行。

然后，依次通過每個字符執行isnumeric並且如果沒有則該字符添加到字符串陣列（），並設置標志，直到isnumeric再次，等....

我希望這會幫助或至少幫助您朝正確的方向發展。

Answer 4

已發布的其他變體：

Sub ZZZ()
    Dim dic As Object: Set dic = CreateObject("Scripting.Dictionary")
    Dim num$, cl As Range, data As Range, key, x
    Dim Result As Worksheet
    Set data = Range([A1], Cells(Rows.Count, "A").End(xlUp))
    For Each cl In data
        x = "": num = "":
        For Each x In Split(cl, " ")
            If IsNumeric(x) Then
                num = x
                dic.Add x, ""
            ElseIf x <> "" And num <> "" Then
                dic(num) = Trim(dic(num) & " " & x)
            End If
        Next x
    Next cl
    Set Result = Worksheets.Add
    With Result
        .Name = "Result " & Replace(Now, ":", "-")
        x = 1
        For Each key In dic
            .Cells(x, "A").Value2 = key
            .Cells(x, "B").Value2 = dic(key)
            x = x + 1
        Next key
        .Columns("A:B").AutoFit
    End With
End Sub

測試：