計算列中的值，忽略重復項

Question

並不是真正的Excel用戶，但是看起來簡單對我來說卻非常困難。 我遇到了麻煩，因為我無法想出一種很好的方法（或者任何一種方法）來使其正常工作。

我在這里：

我需要創建一個新的columnn，它可以告訴每個職業的雇員數量，而忽略重復項（突出顯示）。

數量公式起作用了，所以也許可以使用？ 或者也許只是在路上，應該清除。

只是：= COUNTIFS（A：A; A2）

嘗試搜索了很長時間，沒有找到任何合適的方法。 任何幫助或建議，將不勝感激。 我希望我能清楚地解釋它。

謝謝

Answer 1

沒有輔助列：

D2兩個選項：

{=SUM(--(FREQUENCY(IF($B$2:$B$9=C2,MATCH($A$2:$A$9,$A$2:$A$9,0)),ROW($A$2:$A$9)-ROW($D$1)+1)>0))}

或放在E2 ：

{=SUMPRODUCT((($B$2:$B$9=C2))/COUNTIFS($B$2:$B$9,$B$2:$B$9&"",$A$2:$A$9,$A$2:$A$9&""))}

請注意，這兩個都是數組公式，應通過Ctrl Shift 輸入

Answer 2

添加最后一列，該列是前三列的串聯，然后使用

=SUMPRODUCT(1/COUNTIF(D2:D9,D2:D9))

有這個公式的一個很好的解釋在這里 。 基本上，一次出現的值將計為1。多次出現的值將以其總出現次數的分數形式出現並加起來為1。

如果通過在范圍內選擇一個填充的單元格並按Ctrl + T將數據轉換為Excel表，則公式將自動向下填充最后一列。 然后，您可以引用公式中的表格列，並且在添加行時無需修改公式。

Answer 3

不同的員工職業數

帶有幫助列

唯一值和唯一值是棘手的。 與擴展范圍結合使用時，使用幫助器列有助於識別其中之一：

=SUMPRODUCT((A2=$A$1:$A1)*(C2=$C$1:$C1))
Relative Rows: ^ ^

• 粘貼到單元格E2。
• 復制將公式從粘貼位置向下拖動。

公式向下拖動時，上面標識的相對行號會大大增加。 這將產生越來越大的比較范圍。 范圍不斷擴大。

在這種情況下，擴展范圍是已檢查值的范圍。 很多時候會擴大結果范圍並對其進行測試，以消除結果列表的后續行中已發布結果的重復發布。

• helper列的值是名稱和職業對先前出現過多少次。 零次出現告訴我們這是第一次出現。 我們將只計算主公式中的零（首次出現）。

計算每個職業中不同雇員的主要公式：

=COUNTIFS( $C$2:$C$9, C2, $E$2:$E$9, 0)

• 粘貼到單元格D2。
• 復制將公式從粘貼位置向下拖動。

在這里，我們計算該行的職業的所有行，其中該職業與列出的職業的范圍相匹配，對於職業列表中的該特定行，助手列的行值為零。

Answer 4

SUMPRODUCT陣列中的“交易” 3

您可能在不同的職業（ Tech & Worker, Tech & Economy ）中擁有同名（ David, Michael ）的Tech & Worker, Tech & Economy 。 為了使它們彼此區分，可以在B2中使用：

=SUMPRODUCT((A$2:A$21=A2)*(C$2:C$21=C2))

在D2中，您可以使用：

=SUMPRODUCT((1/B$2:B$21)*(C$2:C$21=C2))