如何提取被調用程序 RAZUGA01 的輸出

Question

我的自定義報告必須調用標准報告RAZUGA01並提取其輸出（以獲取金額）。

以下指令不提取輸出：

  SUBMIT razuga01
    WITH SELECTION-TABLE it_selection
    EXPORTING LIST TO MEMORY
    AND RETURN.

Answer 1

cl_salv_bs_runtime_info=>set( exporting display  = abap_false metadata = abap_false   data = abap_true ).
submit razuga01
    with #Here you parameters from selection screen
    and return.
try.
  "Get data from SALV model
  cl_salv_bs_runtime_info=>get_data_ref( importing r_data = lo_data ).
  assign lo_data->* to <outtab>.
  catch cx_salv_bs_sc_runtime_info.
endtry.
cl_salv_bs_runtime_info=>clear_all( ). 

嘗試使用此代碼，您將能夠從標准報告中獲取 ALV 表

Answer 2

對我來說，這段代碼有效：

DATA: lt_seltab  TYPE TABLE OF rsparams,
      ls_seltab  LIKE LINE OF lt_seltab,
      t_list     TYPE TABLE OF abaplist.

DATA: xlist TYPE TABLE OF abaplist.
DATA: xtext TYPE TABLE OF char200.

ls_seltab-kind    = 'S'.
ls_seltab-sign    = 'I'.
ls_seltab-option  = 'EQ'.

ls_seltab-selname = 'BERDATUM'.          " Name of parameter on submitted program
ls_seltab-low     = '20061231'.
APPEND ls_seltab TO lt_seltab.

ls_seltab-selname = 'BUKRS'.
ls_seltab-low     = '0005'.
APPEND ls_seltab TO lt_seltab.

SUBMIT razuga01 WITH SELECTION-TABLE lt_seltab EXPORTING LIST TO MEMORY AND RETURN.

CALL FUNCTION 'LIST_FROM_MEMORY'
  TABLES
    listobject = xlist.

CALL FUNCTION 'LIST_TO_TXT'
  EXPORTING
    list_index         = -1
  TABLES
    listtxt            = xtext
    listobject         = xlist.

如果它對您不起作用，可能是您在 seltab 中設置了一些錯誤的參數。

當然，您必須進行一些額外的解析才能將這些結果轉換為人類可讀的形式。