我如何添加 OR？

Question

如果是星期四，我只想做些不同的事情。 我也很想列出假期，讓那些也做一些不同的事情，但如果我的第一個問題是星期四。

=IF(WEEKDAY(E3,2)<6, "Wake up", "Sleep")

Answer 1

OR 也沒有必要，而且沒有在我看來更整潔：

=IF(COUNTIF(Holiday,E3),"Other",IF(WEEKDAY(E3)=5,"Remote",IF(WEEKDAY(E3,2)>5,"Sleep","Wake up")))

Holiday是不同日期的命名范圍。

Answer 2

您可以使用OR(c1,c2,...)函數，當其任一參數條件為真時，該函數的計算結果為 True。 例如，

=IF(OR(WEEKDAY(E3,2)=1,WEEKDAY(E3,2)=2,...), "Wake up", IF(OR(...), "Sleep", "Remote"))

Answer 3

OR函數采用參數列表，即OR(param1, param2, param...) 。

下面的公式將在除星期四之外的每一天做一件事（“醒來”）。

=IF(OR(WEEKDAY(E3,2) < 4, WEEKDAY(E3,2) > 4), "Wake Up", "Sleep")

使用您的日期格式 (2)，其中星期四是第 4 天，它表示如果一周中的某一天小於 4 或大於 4，則說“Wake Up”，否則說“Sleep”。

更新

為了適應更新的原始問題，下面的函數將：

• 如果日期是Holiday命名范圍中指定的Holiday --> Holiday
• 如果工作日是星期四 --> 遠程
• 如果工作日是周六或周日 --> 睡眠
• 其他（星期一、星期二、星期三、星期五）-> 起床

=IF(COUNTIF(Holidays,A2)>0,"Holiday",IF(WEEKDAY(A2,2)=4,"Remote",IF(OR(WEEKDAY(A2, 2)=6,WEEKDAY(A2, 2)=7),"Sleep","Wake Up")))

請注意，我還將星期五 7/5 指定為假期。

Answer 4

這將起作用：

=IF(OR(WEEKDAY(E3,2)<3,WEEKDAY(E3,2)=5),"Remote",IF(WEEKDAY(E3,2)=4,"Sleep","Wake up"))

• 周一、周二、周三、周五 - 遠程
• 星期四 - 睡覺
• 周六、周日 - 起床

Answer 5

我知道您已經詢問過使用OR ，並且已經接受了一個答案，但我想指出您還可以使用VLOOKUP使您的邏輯更清晰、更具可讀性。

首先，您可以創建一個包含工作日和查找值的表，如下所示：

+---+-----+-----------+---------+
|   |  A  |     B     |    C    |
+---+-----+-----------+---------+
| 1 | nbr | weekday   | alarm   |
| 2 | 1   | Sunday    | Sleep   |
| 3 | 2   | Monday    | Wake Up |
| 4 | 3   | Tuesday   | Wake Up |
| 5 | 4   | Wednesday | Wake Up |
| 6 | 5   | Thursday  | Remote  |
| 7 | 6   | Friday    | Wake Up |
| 8 | 7   | Saturday  | Sleep   |
+---+-----+-----------+---------+

然后，假設您檢查的日期在E3 ，您可以使用以下公式：

=VLOOKUP(WEEKDAY(E3,1),$A$2:$C$8,3,FALSE)

將查找數據轉換為表格並使用命名范圍時，公式變得更加清晰：

=VLOOKUP(WEEKDAY(date_entered,1),tWeekdays,3,FALSE)