從 Excel VBA 使用密碼創建 MS Access 數據庫文件

Question

我想通過 Excel VBA 創建一個 MS Access 文件.mdb 。 我想通過 Excel VBA 為這個 Access 文件設置一個密碼。

下面的代碼可以創建訪問文件，但沒有密碼。

Sub Example1()
    'the path to create the new access database
    Dim strPath As String
    'an Access object
    Dim objAccess As Object

    strPath = "D:\VBA\NewDB2.mdb"
    Set objAccess = CreateObject("Access.Application")
    Call objAccess.NewCurrentDatabase(strPath)
    objAccess.Quit
End Sub

如何設置密碼？

Answer 1

應該是這樣的

Option Explicit

Public Sub CreatePasswordProtectedDatabase()
    Dim strPath As String
    strPath = "D:\VBA\NewDB2.mdb"

    'create new Access application
    Dim objAccess As Object
    Set objAccess = CreateObject("Access.Application")

    'objAccess.Visible = True 'show or hide Access

    'create new database
    objAccess.NewCurrentDatabase strPath

    'example to add a table
    objAccess.DoCmd.RunSQL "CREATE TABLE Test", False
    objAccess.DoCmd.RunSQL "ALTER TABLE Test add Gender char(1)", False

    'set password
    Dim DbPassword As String
    DbPassword = "your_password"
    objAccess.CurrentProject.Connection.Execute "ALTER DATABASE PASSWORD " & DbPassword & " NULL"

    'close database
    objAccess.CloseCurrentDatabase

    'quit Access application
    objAccess.Quit
End Sub

Answer 2

請注意，如果您使用的是 Office 2007 或更新版本，則必須添加FileFormat參數，以使您的 Access 文件為 mdb 格式：

'create new database
objAccess.NewCurrentDatabase strPath, 10

10，是acNewDatabaseFormatAccess2002常量的值。