Aeson 使用先前解析的默認值解析 JSON

Question

我想解析以下 json：

{
  "defaults": {
    "align": "left"
  },
  "animals": [
    {
      "kind": "cat",
      "name": "Oscar",
      "align": "center"
    },
    {
      "kind": "dog",
      "name": "Max"
    }
  ]
}

解析對齊：

data Align = Left | Center | Right

instance FromJSON Align where
  parseJSON (String "left")   = pure Left
  parseJSON (String "center") = pure Center
  parseJSON (String "right")  = pure Right
  parseJSON _ = fail "Expect one of [left, center, right]."

解析默認值：

data BlockDefaults = BlockDefaults { align :: Align }

-- default value Center if key does not exist
blockDefaults :: BlockDefaults
blockDefaults = BlockDefaults { align = Center }

instance FromJSON BlockDefaults where
  parseJSON = withObject "defaults" $ \o -> BlockDefaults <$> o .:? "align" .!= align blockDefaults

現在我想解析狗和貓。 如果align不存在（如dog ），它應該從默認值（ left ）中獲取值。 所以dog應該變成Dog{name="Max", align=Center}和cat Cat{name="Oscar", align=Left} 。

但是如何訪問parseJSON的默認對齊值？

-- pseudo parse code
instance FromJSON Animal where
  parseJSON = withObject "animal" $ \o ->
    Animal <$>
    o .: "kind" <*>
    o .: "name" <*>
    o .:? "align" .!= <DefaultValue> -- How to access value from defaults object?

我不想再次解析每個動物的默認值，那么如何訪問之前解析的那些默認值？ 假設defaults和其他animals有更多的值。

---

所以動物解析器代碼現在看起來像這樣：

parseAnimal :: BlockDefaults -> Value -> Parser Animal
parseAnimal defaults = withObject "animal" $ \o ->
  Animal <$> 
    o .: "kind" <*>
    o .: "name" <*>
    (
      BlockDefaults <$>
      o .:? "align" .!= align defaults
    )

Answer 1

您不必使用FromJSON類，尤其是在解析可能依賴於運行時數據的情況下。 通過聲明自己的解析器的自由，您可以輕松定義

parseAnimal :: BlockDefaults -> Value -> Parser Animal

---

或者，您可以將Animal概括為一種可以在不知道默認值的情況下進行解析的形式，例如，只需放置一個Maybe 。 例如：

data Animal_ a
  = Animal
      Kind
      Name
      a

type Animal = Animal_ Align

parseAnimal :: Value -> Parser (Animal_ (Maybe Align))
animalWithDefault :: BlockDefaults -> Animal_ (Maybe Align) -> Animal

Answer 2

我的評論建議是使用BlockDefaults -> Animal作為實例。 例如：

#!/usr/bin/env cabal
{- cabal:
     build-depends: base, aeson
-}
{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE FlexibleInstances #-}

import Prelude hiding (Either(..)) -- This is why you don't name your constructors 'Left' and 'Right'
import Data.Aeson

data Align = Left | Center | Right
    deriving (Show)

instance FromJSON Align where
  parseJSON (String "left")   = pure Left
  parseJSON (String "center") = pure Center
  parseJSON (String "right")  = pure Right
  parseJSON _ = fail "Expect one of [left, center, right]."

data BlockDefaults = BlockDefaults { align :: Align }

-- default value Center if key does not exist
blockDefaults :: BlockDefaults
blockDefaults = BlockDefaults { align = Center }

instance FromJSON BlockDefaults where
  parseJSON = withObject "defaults" $ \o -> BlockDefaults <$> o .:? "align" .!= align blockDefaults

data Animal = Animal { kind   :: String
                     , name   :: String
                     , aalign :: Align
                     }
    deriving (Show)

instance FromJSON (BlockDefaults -> Animal) where
    parseJSON = withObject "Animal" $ \o ->
        do k <- o  .: "kind"
           n <- o  .: "name"
           a <- o .:? "align"
           pure $ \def -> Animal k n (maybe (align def) id a)

main :: IO ()
main = print (decode "{ \"kind\": \"k\", \"name\" : \"n\" }" <*> Just blockDefaults :: Maybe Animal)