批處理文件解壓文件並運行 Python 腳本

Question

我有一個項目，我需要解壓縮包含.xls文件的文件，然后運行 ​​Python 腳本將文件轉換為.xlsx 。 我需要通過 Windows 任務計划程序執行 Windows 批處理文件來做到這一點。 我在 Superuser 上找到了一些解壓縮文件的代碼，但它不會循環，您必須明確鍵入要解壓縮的文件的名稱。

這是解壓代碼：

@echo off
setlocal
cd /d %~dp0
Call :UnZipFile "C:\Test Folder\" "C:\Test Folder\File1.zip"
exit /b

:UnZipFile <ExtractTo> <newzipfile>
IF "%~dp0"=="" GOTO Continue
set vbs="%temp%\_.vbs"
if exist %vbs% del /f /q %vbs%
>%vbs%  echo Set fso = CreateObject("Scripting.FileSystemObject")
>>%vbs% echo If NOT fso.FolderExists(%1) Then
>>%vbs% echo fso.CreateFolder(%1)
>>%vbs% echo End If
>>%vbs% echo set objShell = CreateObject("Shell.Application")
>>%vbs% echo set FilesInZip=objShell.NameSpace(%2).items
>>%vbs% echo objShell.NameSpace(%1).CopyHere(FilesInZip)
>>%vbs% echo Set fso = Nothing
>>%vbs% echo Set objShell = Nothing
cscript //nologo %vbs%
if exist %vbs% del /f /q %vbs%

這是我的 Python 代碼：

import win32com.client as win32
import argparse

parser = argparse.ArgumentParser()
parser.add_argument('--sourcefilepath')
parser.add_argument('--sourcefilename')
args = parser.parse_args()

fname = r"{sourcefilepath}{sourcefilename}".format(sourcefilepath=args.sourcefilepath,sourcefilename=args.sourcefilename)

excel = win32.gencache.EnsureDispatch('Excel.Application')
wb = excel.Workbooks.Open(fname)
wb.SaveAs(fname + "x", FileFormat = 56)

wb.Close()                                 
excel.Application.Quit()
quit()

任何幫助都會很棒。

Answer 1

@echo off
setlocal
cd /d "%~dp0" || exit /b 1

for %%A in (*.zip) do (
    call :UnZipFile "%cd%\" "%%~fA"

    for %%B in (*.xls) do (
        echo python mypython.py --sourcefilepath "%cd%" --sourcefilename "%%~nxB"
        del "%%~B"
    )
)
exit /b

:UnZipFile <ExtractTo> <newzipfile>
if "%~dp0" == "" exit /b 1
set "vbs=%temp%\_.vbs"
if exist "%vbs%" del /f /q "%vbs%"

(
    echo Set fso = CreateObject("Scripting.FileSystemObject"^)
    echo If NOT fso.FolderExists("%~1"^) Then
    echo fso.CreateFolder("%~1"^)
    echo End If
    echo set objShell = CreateObject("Shell.Application"^)
    echo set FilesInZip=objShell.NameSpace("%~2"^).items
    echo objShell.NameSpace("%~1"^).CopyHere FilesInZip, 16
    echo Set fso = Nothing
    echo Set objShell = Nothing
) > "%vbs%"

cscript //nologo "%vbs%"
if exist "%vbs%" del /f /q "%vbs%"

只是對需要在echo命令中轉義的特殊字符進行了一些小修正。 將goto continue替換為exit /b 1 。 添加了簡單的for循環以獲取所有 zip 文件名。

它將在當前目錄中獲取 xls 文件，並在 python 腳本完成 SaveAs 任務后刪除 xls 文件。

如果檢查為 OK，則刪除 python 命令前面的echo 。

---

或者試試這個 python 代碼，它執行循環、解壓縮和 xls 到 xlsx。

import win32com.client as win32
import argparse
import glob
import os
import zipfile

def xls_to_xlsx(filename, filepath=None):
    if not filepath:
        filepath = os.getcwd()

    fname = os.path.join(filepath, filename)

    excel = win32.gencache.EnsureDispatch('Excel.Application')
    wb = excel.Workbooks.Open(fname)
    wb.SaveAs(fname + "x", FileFormat = 56)

    wb.Close()
    excel.Application.Quit()

if __name__ == '__main__':
    for zip_file in glob.iglob('*.zip'):
        with zipfile.ZipFile(zip_file) as r:
            r.extractall()

        for xls_file in glob.iglob('*.xls'):
            xls_to_xlsx(xls_file)
            os.remove(xls_file)

它不設置Task Scheduler可以設置的當前工作目錄，或者您可以將其添加到python腳本中進行設置。