[英]Google Sheets Using Weekday in an Arrayformula
我有這個公式,當放入列中的單個單元格時效果很好:
=OR(AND(AND(D2:D, WEEKDAY(NOW()) = 1),D2:D <>""),
AND(AND(E2:E, WEEKDAY(NOW()) = 2),E2:E <>""),
AND(AND(F2:F, WEEKDAY(NOW()) = 2),F2:F <>""),
AND(AND(G2:G, WEEKDAY(NOW()) = 2),G2:G <>""),
AND(AND(H2:H, WEEKDAY(NOW()) = 2),H2:H <>""),
AND(AND(I2:I, WEEKDAY(NOW()) = 2),I2:I <>""),
AND(AND(J2:J, WEEKDAY(NOW()) = 2),J2:J <>"")
)
但是我似乎無法讓它在 arrayformula 中工作:
=ARRAYFORMULA(IF(LEN(A2:A),
OR(AND(AND(D2:D, WEEKDAY(NOW()) = 1),D2:D <>""),
AND(AND(E2:E, WEEKDAY(NOW()) = 2),E2:E <>""),
AND(AND(F2:F, WEEKDAY(NOW()) = 2),F2:F <>""),
AND(AND(G2:G, WEEKDAY(NOW()) = 2),G2:G <>""),
AND(AND(H2:H, WEEKDAY(NOW()) = 2),H2:H <>""),
AND(AND(I2:I, WEEKDAY(NOW()) = 2),I2:I <>""),
AND(AND(J2:J, WEEKDAY(NOW()) = 2),J2:J <>"")
),""))
這是共享的工作表,您可以復制它: https : //docs.google.com/spreadsheets/d/1TR-ayKtfOFC2LtQoIm8kzt7keTsyrqgxP0ZY9JVDcOs/edit?usp=sharing
[更新:] 我原來的公式有另一個錯誤。 PlayerO解決了 AND OR 問題,但繼承了我的錯誤。 這是適用於我的情況的更正代碼:
={"VaildDay";ARRAYFORMULA(IF(LEN(A2:A),
((((E2:E)*(WEEKDAY(NOW())=1))*(E2:E<>""))+
(((F2:F)*(WEEKDAY(NOW())=2))*(F2:F<>""))+
(((G2:G)*(WEEKDAY(NOW())=3))*(G2:G<>""))+
(((H2:H)*(WEEKDAY(NOW())=4))*(H2:H<>""))+
(((I2:I)*(WEEKDAY(NOW())=5))*(I2:I<>""))+
(((J2:J)*(WEEKDAY(NOW())=6))*(J2:J<>""))+
(((K2:K)*(WEEKDAY(NOW())=7))*(K2:K<>"")) = 1, ))
將AND
更改為*
並將OR
更改為+
:
=ARRAYFORMULA(IF(LEN(A2:A),
((((D2:D)*(WEEKDAY(NOW())=1))*(D2:D<>""))+
(((E2:E)*(WEEKDAY(NOW())=2))*(E2:E<>""))+
(((F2:F)*(WEEKDAY(NOW())=2))*(F2:F<>""))+
(((G2:G)*(WEEKDAY(NOW())=2))*(G2:G<>""))+
(((H2:H)*(WEEKDAY(NOW())=2))*(H2:H<>""))+
(((I2:I)*(WEEKDAY(NOW())=2))*(I2:I<>""))+
(((J2:J)*(WEEKDAY(NOW())=2))*(J2:J<>"")))=1, ))
聲明:本站的技術帖子網頁,遵循CC BY-SA 4.0協議,如果您需要轉載,請注明本站網址或者原文地址。任何問題請咨詢:yoyou2525@163.com.