在 IO 中作用於謂詞的慣用 Haskell 方式是什么？

Question

對於一些文件操作，我需要檢查文件是否存在，是否被修改，然后才對其進行一些操作。 我的新手 Haskell 代碼如下（簡化）：

someFileOp ::FileContents -> FilePath -> IO (FileOpResult)
someFileOp contents absFilePath = do
    fileExists <- DIR.doesFileExist absFilePath
    if fileExists
        then do
            isMod <- isModified contents absFilePath
            if isMod
                then return FileModified
            else return $ doSomethingWithFile
        else return FileNotFound

它確實有效。 但是，嵌套的 if 表達式在我看來是錯誤的 - 不像 FP。 檢查 IO 中的幾個 Boolean 條件然后根據它們的結果采取一些行動的慣用方法是什么？

Answer 1

忽略丹尼爾關於比賽的好觀點以及為什么通常不檢查文件，更多的 Haskell 解決方案通常是一個單子變壓器。 這是一個例外變壓器有意義的典型情況。 我還包括了對 ContT 的（錯誤）使用，以防您好奇並想探索：

import System.Directory as DIR
import Control.Monad.Trans.Cont
import Control.Monad
import Control.Monad.IO.Class
import Control.Monad.Trans.Except

isModified :: a -> b -> IO Bool
isModified _ _ = pure False

type FileOpResult = Either String String

someFileOp_cont :: String -> FilePath -> IO FileOpResult
someFileOp_cont contents absFilePath = evalContT $ callCC $ \exit -> do
    fileExists <- liftIO $ DIR.doesFileExist absFilePath
    unless fileExists (exit (Left "FileNotFound"))
    isMod <- liftIO $ isModified contents absFilePath
    when isMod (exit (Left "FileModified"))
    return (Right "doSomethingWithFile")

someFileOp_except :: String -> FilePath -> IO FileOpResult
someFileOp_except contents absFilePath = runExceptT $ do
    fileExists <- liftIO $ DIR.doesFileExist absFilePath
    unless fileExists (throwE "FileNotFound")
    isMod <- liftIO $ isModified contents absFilePath
    when isMod (throwE "FileModified")
    return "doSomethingWithFile"

Answer 2

我會使用whenM:: Monad m => m Bool -> m () -> m()或ifM:: Monad m => m Bool -> ma -> ma -> ma ，例如extra ：

-- | Like 'when', but where the test can be monadic.
whenM :: Monad m => m Bool -> m () -> m ()
whenM mb mt = mb >>= \b ->
  if b
    then mt
    else return ()

-- | Like @if@, but where the test can be monadic.
ifM :: Monad m => m Bool -> m a -> m a -> m a
ifM mb mt me = mb >>= \b ->
  if b
    then mt
    else me

Answer 3

您發布的代碼對我來說看起來不錯。 另一種可能性是在像ExceptT Err IO這樣的短路單子中起作用。

data Err = FileNotFound | FileModified

getFileContents :: FilePath -> ExceptT Err IO FileContents
getFileContents fp = do
    exists <- doesFileExist fp
    if exists then {- ... -} else throwError FileNotFound

someFileOp :: FileContents -> FilePath -> ExceptT Err IO FileOpResult
someFileOp fc fp = do
    fc' <- getFileContents fp
    when (fc /= fc') (throwError FileModified)
    doSomethingWithFile