寫一個相當於mul/imul的VOP

Question

因此，mul 和 imul 指令都將機器字相乘並將結果和溢出存儲在某些寄存器中（例如https://c9x.me/x86/html/file_module_x86_id_210.html ）。 我正在嘗試編寫一個可以完全使用此信息並返回 2 個值的 vop。 這可能嗎？ 我找不到有關如何使 vop 返回多個值的任何信息。 如果有人可以展示整個事物的外觀示例，我也將不勝感激。

編輯：所以我想出了一些東西，但它仍然不夠好。 我會在這里發布，然后解釋問題。

(defpackage #:fixmul
  (:use #:CL)
  (:export #:fixmul))

(in-package #:fixmul)


(sb-c:defknown fixmul (fixnum fixnum) (values fixnum fixnum &optional)
    (sb-c:foldable sb-c:flushable sb-c:movable)
  :overwrite-fndb-silently t)

(in-package #:sb-vm)

(define-vop (fixmul:fixmul)
  (:policy :fast-safe)
  (:translate fixmul:fixmul)
  (:args (x :scs (signed-reg) :target eax)
         (y :scs (signed-reg signed-stack)))
  (:arg-types fixnum fixnum)
  (:args-var args)
  (:temporary (:sc signed-reg :offset eax-offset :target quo
               :from (:argument 0) :to (:result 0)) eax)
  (:temporary (:sc signed-reg :offset edx-offset :target rem
               :from (:argument 0) :to (:result 1)) edx)
  (:results (quo :scs (signed-reg))
            (rem :scs (signed-reg)))
  (:result-types fixnum fixnum)
  (:note "inline (unsigned-byte 64) arithmetic")
  (:vop-var vop)
  (:save-p :compute-only)
  (:generator 5
              (move eax x)
              (inst mul eax y)
              (move quo eax)
              (move rem edx)))

(in-package #:fixmul)

(defun fixmul (a b)
  (fixmul a b))

因此，這反匯編為：

> (disassemble 'fixmul)
; disassembly for FIXMUL
; Size: 35 bytes. Origin: #x52C42F4F                          ; FIXMUL
; 4F:       48F7E7           MUL RAX, RDI
; 52:       488BFA           MOV RDI, RDX
; 55:       48D1E0           SHL RAX, 1
; 58:       48D1E7           SHL RDI, 1
; 5B:       488BD0           MOV RDX, RAX
; 5E:       488D5D10         LEA RBX, [RBP+16]
; 62:       B904000000       MOV ECX, 4
; 67:       BE17001050       MOV ESI, #x50100017              ; NIL
; 6C:       F9               STC
; 6D:       488BE5           MOV RSP, RBP
; 70:       5D               POP RBP
; 71:       C3               RET
NIL

這還不錯，但我不明白我在 sbcl 方面所做的大部分工作，特別是 - 為什么我得到這個 LEA RBX，[RBP+16] 和 MOV ESI，#x50100017
指示？

EDIT2：似乎這些說明主要是關於返回 2 個值。 然而，從某種意義上說，整個事情都是有問題的，因為它使用 CL 原生的 fixnums 等，而不僅僅是原始的機器字。 我不知道如何解決這個問題，這就是為什么我不給出一個自我答案。

Answer 1

嘗試：

(defpackage #:fixmul
  (:use #:CL)
  (:export #:fixmul))

(in-package #:fixmul)

(sb-c:defknown fixmul ((signed-byte 64) (signed-byte 64)) 
               (values (signed-byte 64) (signed-byte 64) &optional)
               (sb-c:foldable sb-c:flushable sb-c:movable))

(in-package #:sb-vm)

(define-vop (fixmul:fixmul)
  (:policy :fast-safe)
  (:translate fixmul:fixmul)
  (:args (x :scs (signed-reg) :target eax)
         (y :scs (signed-reg signed-stack)))
  (:arg-types signed-num signed-num)
  ; (:args-var args)
  (:temporary (:sc signed-reg :offset eax-offset :target quo
               :from (:argument 0) :to (:result 0)) eax)
  (:temporary (:sc signed-reg :offset edx-offset :target rem
               :from (:argument 0) :to (:result 1)) edx)
  (:results (quo :scs (signed-reg))
            (rem :scs (signed-reg)))
  (:result-types signed-num signed-num)
  (:note "inline (unsigned-byte 64) arithmetic")
  (:vop-var vop)
  (:save-p :compute-only)
  (:generator 5
              (move eax x)
              (inst mul eax y)
              (move quo eax)
              (move rem edx)))

(in-package #:fixmul)

(defun fixmul (a b)
  (fixmul a b))

現在：（反匯編'fixmul）

顯示：

; disassembly for FIXMUL
; 02E2D561:       498BC0           MOV RAX, R8                ; no-arg-parsing entry point
;       64:       49F7E1           MUL RAX, R9
;       67:       488BCA           MOV RCX, RDX
;       6A:       486BD002         IMUL RDX, RAX, 2
;       6E:       710E             JNO L0
;       70:       488BD0           MOV RDX, RAX
;       73:       4C8D1C2540060020 LEA R11, [#x20000640]      ; ALLOC-SIGNED-BIGNUM-IN-RDX
;       7B:       41FFD3           CALL R11
;       7E: L0:   486BF902         IMUL RDI, RCX, 2
;       82:       710E             JNO L1
;       84:       488BF9           MOV RDI, RCX
;       87:       4C8D1C2518070020 LEA R11, [#x20000718]      ; ALLOC-SIGNED-BIGNUM-IN-RDI
;       8F:       41FFD3           CALL R11
;       92: L1:   488D5D10         LEA RBX, [RBP+16]
;       96:       B904000000       MOV ECX, 4
;       9B:       BE17001020       MOV ESI, 537919511
;       A0:       F9               STC
;       A1:       488BE5           MOV RSP, RBP
;       A4:       5D               POP RBP
;       A5:       C3               RET
;       A6:       0F0B0A           BREAK 10                   ; error trap
;       A9:       02               BYTE #X02
;       AA:       18               BYTE #X18                  ; INVALID-ARG-COUNT-ERROR
;       AB:       54               BYTE #X54                  ; RCX
NIL

正如你所看到的

; 73: 4C8D1C2540060020 LEA R11, [#x20000640]; ALLOC-SIGNED-BIGNUM-IN-RDX

和

; 87: 4C8D1C2518070020 LEA R11, [#x20000718]; ALLOC-SIGNED-BIGNUM-IN-RDI

分配了一個bignum (and integer (not fixnum)) 。 因為我有一個 64 位系統，所以一個 bignum 適合一個機器字。 反匯編在 32 位系統上會有所不同。 在這種情況下，您可以在sb-c:defknown fixmul中指定(signed-byte 32) 。

您的結果類型和 arg 類型也可以不同（這樣，如果您知道輸入值會很小，那么您仍然可以獲得接近(signed-byte 32)最大值的值的結果。）：

(sb-c:defknown fixmul ((signed-byte 32) (signed-byte 32)) 
               (values (signed-byte 64) (signed-byte 64) &optional)
               (sb-c:foldable sb-c:flushable sb-c:movable))

一些測試：

(fixmul 10000000000000000 100000000000000000)

> 4089650035136921600
  54210108624275


(fixmul 20 -200000)

> -4000000
  19

注意：我必須注釋掉(:args-var args)並取消:overwrite-fndb-silently t才能使我的代碼正常工作。 這可能是由於與您的我的 sbcl 的版本不同。