Power BI：使用不相關的日期表創建度量

Question

嗨，我已經為此苦苦掙扎了一段時間，希望我沒有錯過以前的問題。 我正在嘗試根據 EOMONTH 日期計算我們擁有的車輛數量。 我們定期買賣汽車，為了報告，我們需要知道每個月底有多少輛汽車，報告是滾動的 12 個月。

我嘗試創建與日期表日期的車輛購買日期的關系，但是當我創建度量時（用於計算已購買但尚未售出的車輛數量）：

SalesBlank = CALCULATE(COUNT(Vehicles[MVANumber]), FILTER(Vehicles, Vehicles[purchasedate] <= RELATED('Date'[EOMONTH]) && ISBLANK(Vehicles[saledate])))

我只計算了當月購買的車輛數量並且沒有銷售日期——我並不感到驚訝，因為我與日期表的關系就是購買日期。

如何設置度量來查看日期表並使用以下邏輯過濾車輛表：購買 <= date[EOMONTH] && ISBLANK(salesdate)

任何幫助將不勝感激，！ 謝謝，馬特

樣本數據和所需結果

關系

Answer 1

如果我理解正確的話，你想在每個月底對手頭的車輛進行計數。 這可以通過計算購買日期小於或等於所選月末的車輛數並減去銷售日期小於或等於所選月末的車輛數來計算。

您可以在 Vehicle[PurchaseDate] 和 Date[Date] 之間創建活動關系。 然后根據 Vehicles[SaleDate] 和 Date[Date] 創建一個非活動關系。

您可以使用類似這樣的度量：

Inventory Count =
VAR MaxDate =
    MAX ( 'Date'[Date] )
VAR MinDate =
    CALCULATE ( MIN ( 'Date'[Date] ), ALL ( 'Date' ) )
VAR Purch =
    CALCULATE (
        COUNT ( 'Vehicles'[VehicleID] ),
        DATESBETWEEN ( 'Date'[Date], MinDate, MaxDate )
    )
VAR Sales =
    CALCULATE (
        COUNT ( 'Vehicles'[VehicleID] ),
        USERELATIONSHIP ( 'Date'[Date], Vehicles[Sale Date] ),
        DATESBETWEEN ( 'Date'[Date], MinDate, MaxDate )
    )
VAR MaxPurDt =
    CALCULATE ( MAX ( 'Vehicles'[Purchase Date] ), ALL ( 'Vehicles' ) )
VAR MaxSlDt =
    CALCULATE ( MAX ( 'Vehicles'[Sale Date] ), ALL ( 'Vehicles' ) )
RETURN
    IF (
        MIN ( 'Date'[Date] ) <= MaxPurDt
            || MIN ( 'Date'[Date] ) <= MaxSlDt,
        Purch - Sales
    )

此度量獲取購買的累積計數和銷售的累積計數，然后將它們減去。 IF 檢查是為了避免累積總計傳播超出 Vehicle 表中的最大日期。

我不確定如何解釋您在預期結果中僅顯示 3 個月。 這將產生與您所擁有的答案相同的答案，但沒有對表格應用過濾器，它從 2016 年 3 月 31 日（首次銷售日期）開始。

編輯：按照您的想法，可能有一種更有效的方法，但目前我是 escaping。