查詢結果 Google 表格中的 VLookup 列

Question

我正在為 4-6 年級的 Google 表格中的學校開發行為圖表系統。 去年我創建了一個不錯的系統，但它嚴重依賴 vlookup，更新速度非常慢，尤其是在輸入更多數據時。

今年，我嘗試使用查詢來更新它，這要快得多，但我遇到了困難，我需要查詢在單獨的表中查找值。

所以，我把它放在列出被記過的學生的位置，並顯示他們在當前日期有多少記過：

=query('Form Responses 1'!A:D,"
select C,count(C)
where A>=  datetime '"&TEXT(today(),"yyyy-mm-dd HH:mm:ss")&"' and 
A<  datetime '"&TEXT(today()+time(12,0,0),"yyyy-mm-dd HH:mm:ss")&"' and D != '6 - Late Assignments (WE)'
group by C order by count(C) desc
label C 'Student Name', count(C) 'Number of Marks'")

但現在我需要第三列，其結果基於計數。 我們在學校的行為系統是這樣的，如果一個孩子得到 1 分，那就是警告，2 是休課懲罰，等等。每個年級都有不同的后果，所以我需要它從單獨的表中查找數據並顯示孩子要接受的結果。 通常我會通過使用 vlookup 或選擇 function 來解決這個問題，但我不知道如何在查詢中實現它，或者我是否需要使用嵌套查詢？

所以，現在我的結果是這樣的：

Student Name | Number of Marks
Abby Alpha | 1
Benny Beta | 2
Gort Gamma | 27

但我需要它返回如下內容：

Student Name | Number of Marks | Consequence
Abby Alpha | 1  | Warning
Benny Beta | 2  | Walking at Recess
Gort Gamma | 7 | Office

其中，后果是根據在簡單表中查找第二列的結果來確定的，如果標記數超過表中的最大數量，它應該返回最大可能的結果。

我會很感激任何建議，我只是一名小學老師，所以雖然弄清楚它很有趣。 這有點超出我的舒適區。 謝謝！

Answer 1

嘗試：

=ARRAYFORMULA(IFNA(VLOOKUP(B2:B, E:F, 2, 0)))

---

更新：

粘貼在 C3 中：

=ARRAYFORMULA(IFNA(VLOOKUP(B3:B, Sheet3!A:B, 2, 0)))

粘貼在 F3 中：

=ARRAYFORMULA(IFNA(VLOOKUP(E3:E, Sheet3!A:B, 2, 0)))

---

更新2：

=ARRAYFORMULA({QUERY('Form Responses 1'!A:C,
 "select C,count(C)
  where A >= datetime '"&TEXT(TODAY(), "yyyy-mm-dd hh:mm:ss")&"'  
    and A <  datetime '"&TEXT(TODAY()+TIME(12, 0, 0), "yyyy-mm-dd hh:mm:ss")&"'
  group by C
  label count(C)'Number of Marks'"), IFNA(VLOOKUP(QUERY('Form Responses 1'!A:C,
 "select count(C)
  where A >= datetime '"&TEXT(TODAY(), "yyyy-mm-dd hh:mm:ss")&"'  
    and A <  datetime '"&TEXT(TODAY()+TIME(12, 0, 0), "yyyy-mm-dd hh:mm:ss")&"'
  group by C
  label count(C)'Number of Marks'"), 
 {"Number of Marks", "Consequence"; Sheet3!A:B}, 2, 0))})