解析器（Yacc）似乎忽略了語法中的標記

Question

解析類似 c 的示例代碼，我有以下問題。 它就像某些標記，如標識符，被語法忽略，導致非原因語法錯誤。

解析器代碼：

%{
#include <stdio.h>
#include <stdlib.h>

int yylex();
void yyerror (char const *);

%}

%token T_MAINCLASS T_ID T_PUBLIC T_STATIC T_VOID T_MAIN T_PRINTLN T_INT T_FLOAT T_FOR T_WHILE T_IF T_ELSE T_EQUAL T_SMALLER T_BIGGER T_NOTEQUAL T_NUM T_STRING

%left '(' ')'
%left '+' '-'
%left '*' '/'
%left '{' '}'
%left ';' ','
%left '<' '>'

%% 
        
PROGRAM     : T_MAINCLASS T_ID '{' T_PUBLIC T_STATIC T_VOID T_MAIN '(' ')' COMP_STMT '}'
        ;

COMP_STMT   : '{' STMT_LIST '}'
        ;
    
STMT_LIST   : /* nothing */
        | STMT_LIST STMT
        ;

STMT        : ASSIGN_STMT
        | FOR_STMT
        | WHILE_STMT
        | IF_STMT
        | COMP_STMT
        | DECLARATION
        | NULL_STMT
        | T_PRINTLN '(' EXPR ')' ';'
        ;

DECLARATION : TYPE ID_LIST ';'
        ;

TYPE        : T_INT
        | T_FLOAT
        ;

ID_LIST     : T_ID ',' ID_LIST
        |
        ;

NULL_STMT   : ';'
        ;

ASSIGN_STMT : ASSIGN_EXPR ';'
        ;

ASSIGN_EXPR : T_ID '=' EXPR
        ;

EXPR        : ASSIGN_EXPR
        | RVAL
        ;

FOR_STMT    : T_FOR '(' OPASSIGN_EXPR ';' OPBOOL_EXPR ';' OPASSIGN_EXPR ')' STMT
        ;

OPASSIGN_EXPR   : /* nothing */
        | ASSIGN_EXPR
        ;

OPBOOL_EXPR : /* nothing */
        | BOOL_EXPR
        ;

WHILE_STMT  : T_WHILE '(' BOOL_EXPR ')' STMT
        ;

IF_STMT     : T_IF '(' BOOL_EXPR ')' STMT ELSE_PART
        ;

ELSE_PART   : /* nothing */
        | T_ELSE STMT
        ;

BOOL_EXPR   : EXPR C_OP EXPR
        ;

C_OP        : T_EQUAL | '<' | '>' | T_SMALLER | T_BIGGER | T_NOTEQUAL
        ;

RVAL        : RVAL '+' TERM
        | RVAL '-' TERM
        | TERM
        ;

TERM        : TERM '*' FACTOR
        | TERM '/' FACTOR
        | FACTOR
        ;

FACTOR      : '(' EXPR ')'
        | T_ID
        | T_NUM
        ;

%%

void yyerror (const char * msg)
{
  fprintf(stderr, "C-like : %s\n", msg);
  exit(1);
}

int main ()
{
  if(!yyparse()){
    printf("Compiled !!!\n");
   }
}

詞法掃描器代碼的一部分：

{Empty}+    { printf("EMPTY ") ; /* nothing */ }

"mainclass" { printf("MAINCLASS ") ; return  T_MAINCLASS ; }

"public"    { printf("PUBLIC ") ; return T_PUBLIC; }
    
"static"    { printf("STATIC ") ; return T_STATIC ; }

"void"      { printf("VOID ") ; return T_VOID ; }

"main"      { printf("MAIN ") ; return T_MAIN ; }

"println"   { printf("PRINTLN ") ; return T_PRINTLN ; }

"int"       { printf("INT ") ; return T_INT ; }

"float"     { printf("FLOAT ") ; return T_FLOAT ; }

"for"       { printf("FOR ") ; return T_FOR ; }

"while"     { printf("WHILE ") ; return T_WHILE ; }

"if"        { printf("IF ") ; return T_IF ; }

"else"      { printf("ELSE ") ; return T_ELSE ; }

"=="        { printf("EQUAL ") ; return T_EQUAL ; }

"<="        { printf("SMALLER ") ; return T_SMALLER ; }

">="        { printf("BIGGER ") ; return T_BIGGER ; }

"!="        { printf("NOTEQUAL ") ; return T_NOTEQUAL ; }

{id}        { printf("ID ") ; return T_ID ; }

{num}       { printf("NUM ") ; return T_NUM ; }

{string}    { printf("STRING ") ; return T_STRING ; }

{punct}     { printf("PUNCT ") ; return yytext[0] ; }

<<EOF>>     { printf("EOF ") ; return T_EOF; }

.       { yyerror("lexical error"); exit(1); }

例子：

mainclass Example {
       public static void main ( )
       {
         int c;
         float x, sum, mo;
         c=0;
         x=3.5;
         sum=0.0;
         while (c<5)
         {
                  sum=sum+x;
                  c=c+1;
                 x=x+1.5;
        }
       mo=sum/5;
       println (mo);
       }
}

運行所有這些東西，它出現了這個 output：

C-like : syntax error
MAINCLASS EMPTY ID 

似乎 id 錯誤 position 盡管在語法上我們有：

PROGRAM     : T_MAINCLASS T_ID '{' T_PUBLIC T_STATIC T_VOID T_MAIN '(' ')' COMP_STMT '}'

Answer 1

根據OP's self answer中提出的“解決方案”，很明顯最初的問題是生成的用於編譯掃描儀的 header 與 bison/yacc 從解析器規范生成的 header 不同。

生成的 header 包括所有令牌類型的定義為小整數； 為了讓掃描器與解析器通信，它必須用正確的標記類型識別每個標記。 因此解析器生成器（bison/yacc）根據解析器規范（ .y文件）生成 header，並且 header 必須在生成的掃描器中#include d，以便掃描器操作可以使用符號令牌類型名稱。

如果掃描器是使用從解析器規范的某個先前版本生成的 header 文件編譯的，則很可能令牌編號不再與解析器所期望的一致。

避免這個問題的最簡單方法是使用像make這樣的構建系統，它會在必要時自動重新編譯掃描儀。

檢測此問題的最簡單方法是使用 bison 的內置跟蹤工具。 啟用跟蹤只需要幾行代碼，並且使您不必在整個掃描儀和解析器中分散printf語句。 野牛軌跡會准確地告訴你發生了什么，所以它不僅比添加printf的工作量少，而且更精確。 特別是，它報告傳遞給解析器的每個標記（並且，稍加努力，您也可以讓它報告這些標記的語義值）。 因此，如果解析器得到錯誤的令牌代碼，您會立即看到。

Answer 2

經過許多潛在的有用更改后，解析器通過更改這些標記的順序來工作。

• 從

  %token T_MAINCLASS T_ID T_PUBLIC T_STATIC T_VOID T_MAIN T_PRINTLN T_INT T_FLOAT T_FOR T_WHILE T_IF T_ELSE T_EQUAL T_SMALLER T_BIGGER T_NOTEQUAL T_NUM T_STRING

• 至

  %token T_MAINCLASS T_PUBLIC T_STATIC T_VOID T_MAIN T_PRINTLN T_INT T_FLOAT T_FOR T_WHILE T_IF T_EQUAL T_ID T_NUM T_SMALLER T_BIGGER T_NOTEQUAL T_ELSE T_STRING

看起來閱讀元素是else ，但詞法分析器通常返回一個 id。 不知何故，這種修改是解決方案。