如何將復雜的 Xml 轉換為 csv？

Question

我正在用java（初級）編寫一個程序，我真的需要xslt轉換方面的幫助。 需要從 xml 制作 csv 文件。 我得到了這個 xslt 過濾器：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text" omit-xml-declaration="yes" indent="no"/>

    <xsl:template match="node()" name="conv">
        <xsl:call-template name="loop"/>
    </xsl:template>

    <xsl:template name="loop">

        <xsl:for-each select="./*[count(*) = 0]">
            <xsl:value-of select="."/>
            <xsl:if test="position() != last()">
                <xsl:text>,</xsl:text>
            </xsl:if>
            <xsl:if test="position() = last()">
                <xsl:text>,</xsl:text>
            </xsl:if>
        </xsl:for-each>
        <xsl:text>&#xA;</xsl:text>


        <xsl:for-each select="./*[(count(*) != 0) and (name()!='PARAMETRS')] ">
            <xsl:call-template name="loop"/>
        </xsl:for-each>
            <xsl:text>&#xA;</xsl:text>
    </xsl:template>
</xsl:stylesheet>

來源 xml：

<Integration>
    <PARAMETRS>
        <ID>AZD</ID>
        <DATE>2020-01-01</DATE>
    </PARAMETRS>
    <ORG>
        <Thing>
            <object>10220</object>
            <type>U</type>
            <dyn>
                <items>
                    <val>988009</val>
                    <datebegin>2019-12-12</datebegin>
                </items>
            </dyn>
        </Thing>
        <Thing>
            <object>10221</object>
            <type>U</type>
            <dyn>
                <items>
                    <val>988010</val>
                    <datebegin>2019-12-13</datebegin>
                </items>
                <items>
                    <val>988011</val>
                    <datebegin>2019-12-14</datebegin>
                </items>
            </dyn>
        </Thing>
    </ORG>
</Integration>

在 output 中，我得到了逗號分隔的行，以及更多具有以下值的行（那些相同的項目）。 並且無法弄清楚如何連接這些值......我會通過 select = "concat" 的值來做到這一點，但我可能有幾個 dyn (1, 2, 3...)，因此這不合適。 output 需要用逗號分隔的 csv。 請告知如何將項目與其父級連接起來？ 或者有更簡單的方法來解析 xml 具有不同數量的小節（孩子）。

預期 output：

10220,U,988009,2019-12-12
10221,U,988010,2019-12-13,988011,2019-12-14

Answer 1

您展示的 output 可以使用以下樣式表輕松獲得：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>

<xsl:template match="/Integration">
    <xsl:for-each select="ORG/Thing">
        <xsl:value-of select="object"/>
        <xsl:text>,</xsl:text>
        <xsl:value-of select="type"/>
        <xsl:text>,</xsl:text>
        <xsl:for-each select="dyn/items">
            <xsl:value-of select="val"/>
            <xsl:text>,</xsl:text>
            <xsl:value-of select="datebegin"/>
            <xsl:if test="position() != last()">
                <xsl:text>,</xsl:text>
            </xsl:if>
        </xsl:for-each>
        <xsl:text>&#xA;</xsl:text>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

---

請注意，output 對每個items都有一組列； 這不是一個理想的 CSV 結構。

Answer 2

如果您可以使用 XSLT 2.0，它將開辟新的強大功能。

Oracle XML 開發人員套件 (XDK) 支持 XSLT 2.0

這是鏈接： 使用 XSLT 處理器用於 Java

下面的方法正在執行以下操作：

• 使用string-join() function 通過.//*/(text()[1]表達式連接不同層次級別上的所有子元素值。
• xs:token轉換會刪除空格。
• XPath 謂詞[. != ''] [. != '']刪除空序列成員。

XSLT 2.0

<?xml version='1.0'?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xsl:output method="text"/>

    <xsl:template match="/Integration">
        <xsl:for-each select="ORG/Thing">
            <xsl:value-of select="string-join((.//*/(text()[1] cast as xs:token?))[. != ''],',')"/>
            <xsl:text>&#xA;</xsl:text>
        </xsl:for-each>
    </xsl:template>

</xsl:stylesheet>

Output

10220,U,988009,2019-12-12
10221,U,988010,2019-12-13,988011,2019-12-14

基於Marting Honnen的大技巧，這里更簡潔的XSLT 2.0版本沒有任何循環。

XSLT 2.0

<?xml version="1.0"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xsl:output method="text"/>

    <xsl:template match="/Integration">
        <xsl:value-of select="ORG/Thing/string-join((.//*/(text()[1] cast as xs:token?))[. != ''],',')" separator="&#xA;"/>
    </xsl:template>
</xsl:stylesheet>