用Excel VBA導入web數據

Question

我希望當我導入產品的網站 URL 時，它會將產品的名稱、描述、價格和圖像 URL 顯示到電子表格中。

這是我所擁有的：（不是真正的網站）

Sub Trial() Dim ieObj As InternetExplorer Dim ht As HTMLDocument
    
    Website = "https://www.amazon.com/resistencia-Avalon-cartas-empaque-original/dp/B009SAAV0C?pf_rd_r=WWESR922Z214Y10K3PHH&pf_rd_p=4dd821c0-e689-433a-a035-5e03461484eb&pd_rd_r=305599f9-5f3f-41c6-9a13-8daefd8d998c&pd_rd_w=qWHso&pd_rd_wg=BNzqC&ref_=pd_gw_unk"
    
    Set ieObj = New InternetExplorer ieObj.Visible = True ieObj.navigate Website
    
    Do Until ieObj.readyState = READYSTATE_COMPLETE DoEvents Loop
    
    Set ht = ieObj.document
    
End Sub

附加信息
產品名稱：反抗軍：阿瓦隆社交推理游戲
id="productTitle" class="a-size-large product-title-word-break"

產品描述： The Resistance: Avalon 是一款單機游戲，而 The Resistance 不是必須玩的； 游戲是兼容的，可以組合
適合 5 到 10 名玩家
需要 30 分鍾的游戲時間
（全部在 class = "a-list-item" 但不同的部分）

價格：17.12 美元
id="priceblock_ourprice"
class="a-size-medium a-color-price priceBlockBuyingPriceString"

圖片 URL： https://images-na.ssl-images-amazon.com/images/I/91JhcC33dTL._AC_SY879_.jpg
img alt="反抗軍：阿瓦隆社會演繹游戲"

Answer 1

您可以使用 xhr 而不是 IE 來獲取上述字段。 它肯定會使執行速度更快並為您節省大量時間。 我只使用正則表達式來隔離所需的圖像鏈接。 執行前確保將Microsoft HTML Object Library添加到參考庫中。

Sub GetContent()
    Const URL = "https://www.amazon.com/resistencia-Avalon-cartas-empaque-original/dp/B009SAAV0C?pf_rd_r=WWESR922Z214Y10K3PHH&pf_rd_p=4dd821c0-e689-433a-a035-5e03461484eb&pd_rd_r=305599f9-5f3f-41c6-9a13-8daefd8d998c&pd_rd_w=qWHso&pd_rd_wg=BNzqC&ref_=pd_gw_unk"
    Dim S$, sImage$, Matches As Object

    With CreateObject("MSXML2.XMLHTTP")
        .Open "GET", URL, False
        .setRequestHeader "User-Agent", "Mozilla/5.0 (Windows NT 6.1; rv:79.0) Gecko/20100101 Firefox/79.0"
        .send
        S = .responseText
    End With
    
    With New HTMLDocument
        .body.innerHTML = S
        [A1] = .querySelector("h1#title > span#productTitle").innerText
        [B1] = Trim(Split(.querySelector("#feature-bullets > ul.a-unordered-list").innerText, "model number.")(1))
        [C1] = .querySelector("span[id='priceblock_ourprice']").innerText
        sImage = .querySelector("#imgTagWrapperId > img").getAttribute("data-a-dynamic-image")
    End With
    
    With CreateObject("VBScript.RegExp")
        .Global = True
        .IgnoreCase = False
        .Pattern = """(.*?)"""
        .MultiLine = True
        Set Matches = .Execute(sImage)
        [D1] = Matches(2).submatches(0)
    End With
End Sub