在 dataweave 2.0 中從 var 創建 XML 屬性

Question

我有一個 JSON 輸入：

{
  abc: "",
  def: "hello"

}

我想讓這個空白元素在 XML 中可以為 nillable ie 。 我正在使用以下 dataweave 代碼：

%dw 2,0
output application/xml skipNullOn="everywhere"
var makeNil= (in) ->
in match {
case is Array -> in map makeNil($)
case is Object -> in mapObject (
if ( ($) == "")
  ($$) @(xsi#'nil':true): {}
else ($$): makeNil($)
)
else -> in
}
---
makeNil(payload)

我無法使用 @(xsi#'nil':true) 為 key($$) 創建屬性。 請幫我

Answer 1

解決我在評論中提到的錯誤，添加根元素有效。 請記住，與 JSON 不同，XML 需要一個根元素。

%dw 2.0
output application/xml skipNullOn="everywhere"
ns xsi http://www.w3.org/2001/XMLSchema-instance
var makeNil= (in) ->
    in match {
        case is Array -> in map makeNil($)
        case is Object -> in mapObject (
            if ( ($) == "")
                ($$) @(xsi#'nil':true): {}
            else ($$): makeNil($)
        )
        else -> in
    }
---
top: makeNil(payload)

輸入：

{
  "abc": "",
  "def": "hello"
}

輸出：

<?xml version='1.0' encoding='UTF-8'?>
<top>
  <abc xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:nil="true"/>
  <def>hello</def>
</top>